git.roojs.org Git - app.Builder.js/blob - src/Builder4/WindowState.vala

   1 /**
   2  * as state management is a bit too complicated inside the builder
   3  * it's better to seperate this into this class
   4  *
   5  * This class has references to all the Class instances that make up the window..
   6  *
   7  */
   8 public class WindowState : Object
   9 {
  10     public Xcls_MainWindow win;
  11
  12     public enum State {
  13         NONE,
  14         PREVIEW,
  15         OBJECT,
  16         PROP,
  17         LISTENER,
  18         CODE,
  19         FILES,
  20         PROJECT // project settings..
  21     }
  22
  23     public State state = State.NONE;
  24
  25     public bool children_loaded = false;
  26
  27
  28     public Xcls_WindowLeftTree  left_tree;
  29     public Xcls_WindowAddProp   add_props;
  30     public Xcls_LeftProps       left_props;
  31     public Xcls_ProjectSettings projectsettings;
  32     public ValaProjectSettings  vala_projectsettings;
  33     public Xcls_RightPalete     rightpalete;
  34     public Editor               code_editor;
  35     public Xcls_WindowRooView   window_rooview;
  36     public Xcls_GtkView         window_gladeview;
  37     public Xcls_DialogNewComponent new_file_dialog;
  38     public Xcls_ClutterFiles     clutterfiles;
  39
  40     public Xcls_WindowLeftProjects left_projects; // can not see where this is initialized..
  41     // ctor
  42     public WindowState(Xcls_MainWindow win)
  43     {
  44         this.win = win;
  45         // initialize
  46
  47         // left elements..
  48         this.leftTreeInit();
  49         this.propsListInit();
  50
  51         // on clutter space...
  52         this.projectEditInit();
  53         this.codeEditInit();
  54         this.projectListInit();
  55         this.fileViewInit();
  56
  57         // adding stuff
  58         this.objectAddInit();
  59         this.propsAddInit();
  60
  61
  62         // previews...
  63         this.gtkViewInit();
  64         this.webkitViewInit();
  65
  66         // dialogs
  67
  68         this.fileNewInit();
  69
  70         this.children_loaded = true;
  71     }
  72
  73
  74     // left tree
  75
  76     public void leftTreeInit()
  77     {
  78
  79         this.left_tree = new Xcls_WindowLeftTree();
  80         this.left_tree.ref();
  81         this.left_tree.main_window = this.win;
  82
  83         this.win.tree.el.pack_start(this.left_tree.el,true, true,0);
  84         this.left_tree.el.show_all();
  85
  86         this.left_tree.before_node_change.connect(() => {
  87             return this.leftTreeBeforeChange();
  88
  89         });
  90
  91         this.left_tree.node_selected.connect((sel) => {
  92             this.leftTreeNodeSelected(sel);
  93         });
  94
  95         this.left_tree.changed.connect(() => {
  96             this.window_rooview.requestRedraw();
  97             this.left_tree.model.file.save();
  98         });
  99
 100     }
 101
 102     public bool leftTreeBeforeChange()
 103     {
 104         if (this.state != State.CODE) {
 105             this.left_props.finish_editing();
 106             return true;
 107         }
 108         if (!this.code_editor.saveContents()) {
 109             return false;
 110         }
 111         return false;
 112     }
 113
 114     public void leftTreeNodeSelected(JsRender.Node? sel)
 115     {
 116
 117         print("node_selected called %s\n", (sel == null) ? "NULL" : "a value");
 118
 119         if (sel == null) {
 120             this.left_props.el.hide();
 121         }
 122         this.left_props.el.show();
 123         this.left_props.load(this.left_tree.getActiveFile(), sel);
 124         switch (this.state) {
 125
 126             case State.OBJECT:
 127
 128                  if (sel == null) {
 129                     this.rightpalete.clear();
 130                     break;
 131                 }
 132                 this.rightpalete.load(this.left_tree.getActiveFile().palete(), sel.fqn());
 133                 break;
 134
 135
 136            case State.PROP:
 137                 if (sel == null) {
 138                     this.add_props.clear();
 139                     break;
 140                 }
 141                 this.add_props.show(this.left_tree.getActiveFile().palete(), "props", sel.fqn());
 142                 break;
 143
 144             case State.LISTENER:
 145
 146                 if (sel == null) {
 147                     this.add_props.clear();
 148                     break;
 149                 }
 150                 this.add_props.show(this.left_tree.getActiveFile().palete(), "signals", sel.fqn());
 151                 break;
 152
 153             case State.CODE:
 154                  this.switchState(State.PREVIEW);
 155
 156                 break;
 157
 158
 159         }
 160
 161
 162     }
 163
 164
 165
 166
 167     public void propsListInit()
 168     {
 169
 170         this.left_props =new Xcls_LeftProps();
 171         this.left_props.ref();
 172         this.left_props.main_window = this.win;
 173         this.win.props.el.pack_start(this.left_props.el,true, true,0);
 174         this.left_props.el.show_all();
 175
 176         this.left_props.show_editor.connect( (file, node, type,  key) => {
 177             this.switchState(State.CODE);
 178             this.code_editor.show(
 179                 file,
 180                 node,
 181                 type,
 182                 key
 183             );
 184
 185
 186         });
 187
 188
 189         this.left_props.stop_editor.connect( () => {
 190             if (this.state != State.CODE) {
 191                 return true;
 192             }
 193
 194             var ret =  this.code_editor.saveContents();
 195             if (!ret) {
 196                 return false;
 197             }
 198             this.switchState(State.PREVIEW);
 199             return ret;
 200         });
 201
 202         this.left_props.changed.connect(() => {
 203               if (this.left_tree.getActiveFile().xtype == "Roo" ) {
 204                    this.win.window_rooview.requestRedraw();
 205
 206                } else {
 207                   this.win.window_gladeview.loadFile(this.left_tree.getActiveFile());
 208               }
 209               this.left_tree.model.updateSelected();
 210               this.left_tree.model.file.save();
 211         });
 212
 213
 214
 215     }
 216
 217     //-------------  projects edit
 218
 219     public void projectEditInit()
 220     {
 221         this.projectsettings  =new Xcls_ProjectSettings();
 222         this.projectsettings.ref();  /// really?
 223
 224         this.vala_projectsettings  =new ValaProjectSettings();
 225         this.vala_projectsettings.ref();
 226         this.vala_projectsettings.window = this.win;
 227
 228         ((Gtk.Container)(this.win.projecteditview.el.get_widget())).add(this.projectsettings.el);
 229         //this.projectsettings.el.show_all();
 230
 231         var stage = this.win.projecteditview.el.get_stage();
 232         stage.set_background_color(  Clutter.Color.from_string("#000"));
 233
 234         this.projectsettings.buttonPressed.connect((btn) => {
 235              if (this.left_tree.getActiveFile().xtype == "Roo" ) {
 236                 if (btn == "save") {
 237                     this.window_rooview.view.renderJS(true);
 238                 }
 239                 if (btn == "apply") {
 240                     this.window_rooview.view.renderJS(true);
 241                     return;
 242                 }
 243             } else {
 244                 // do nothing for gtk..
 245             }
 246             if (btn == "save" || btn == "apply") {
 247                 this.win.project.save();
 248
 249             }
 250             this.switchState (State.PREVIEW);
 251
 252          });
 253
 254     }
 255     // ----------- object adding
 256     public void objectAddInit()
 257     {
 258
 259         this.rightpalete  = new Xcls_RightPalete();
 260         this.rightpalete.ref();  /// really?
 261         ((Gtk.Container)(this.win.objectview.el.get_widget())).add(this.rightpalete.el);
 262         //this.projectsettings.el.show_all();
 263
 264         var stage = this.win.objectview.el.get_stage();
 265         stage.set_background_color(  Clutter.Color.from_string("#000"));
 266
 267     }
 268
 269     // -----------  properties adding list...
 270     // listener uses the properties
 271     public void propsAddInit()
 272     {
 273     // Add properties
 274         this.add_props  = new Xcls_WindowAddProp();
 275         this.add_props.ref();  /// really?
 276         ((Gtk.Container)(this.win.addpropsview.el.get_widget())).add(this.add_props.el);
 277         //this.projectsettings.el.show_all();
 278
 279         var  stage = this.win.addpropsview.el.get_stage();
 280         stage.set_background_color(  Clutter.Color.from_string("#000"));
 281
 282
 283         this.add_props.select.connect( (key,type,skel, etype) => {
 284             this.left_props.addProp(etype, key, skel, type);
 285         });
 286
 287     }
 288     public void propsAddShow()
 289     {
 290
 291     }
 292     public void propsAddHide()
 293     {
 294
 295     }
 296
 297
 298
 299
 300     // ----------- Add / Edit listener
 301     // listener uses the properties
 302     //public void listenerInit()     { }
 303     public void listenerShow()
 304     {
 305
 306     }
 307     public void listenerHide()
 308     {
 309
 310     }
 311
 312     // -------------- codeEditor
 313
 314     public void codeEditInit()
 315     {
 316         this.code_editor  = new  Editor();
 317         this.code_editor.ref();  /// really?
 318         ((Gtk.Container)(this.win.codeeditview.el.get_widget())).add(this.code_editor.el);
 319         //this.projectsettings.el.show_all();
 320
 321         var stage = this.win.codeeditview.el.get_stage();
 322         stage.set_background_color(  Clutter.Color.from_string("#000"));
 323         // editor.save...
 324
 325         this.code_editor.save.connect( () => {
 326              this.left_tree.model.file.save();
 327              this.left_tree.model.updateSelected();
 328         });
 329
 330     }
 331
 332     // ----------- list of projects on left
 333     public void  projectListInit()
 334     {
 335
 336         this.left_projects = new Xcls_WindowLeftProjects();
 337          this.left_projects.ref();
 338          this.win.leftpane.el.pack_start(this.left_projects.el,true, true,0);
 339          this.left_projects.el.show_all();
 340          this.left_projects.project_selected.connect((proj) => {
 341             proj.scanDirs();
 342             this.clutterfiles.loadProject(proj);
 343
 344          });
 345
 346     }
 347     // ----------- file view
 348
 349     public void fileViewInit()
 350     {
 351         var stage = this.win.rooview.el.get_stage(); // seems odd...
 352         this.clutterfiles = new Xcls_ClutterFiles();
 353         this.clutterfiles.ref();
 354         stage.add_child(this.clutterfiles.el);
 355         this.clutterfiles.el.show_all();
 356
 357
 358         this.clutterfiles.open.connect((file) => {
 359             this.fileViewOpen(file);
 360         });
 361
 362     }
 363     public void fileNewInit()
 364     {
 365         this.new_file_dialog = new Xcls_DialogNewComponent();
 366         // force it modal to the main window..
 367         this.new_file_dialog.el.set_transient_for(this.win.el);
 368         this.new_file_dialog.el.set_modal(true);
 369
 370         this.new_file_dialog.success.connect((project,file) =>
 371         {
 372             this.fileViewOpen(file);
 373         });
 374
 375     }
 376
 377
 378     public void fileViewOpen(JsRender.JsRender file)
 379     {
 380         this.win.project = file.project;
 381         this.switchState (State.PREVIEW);
 382
 383         this.left_tree.model.loadFile(file);
 384
 385         var ctr= ((Gtk.Container)(this.win.rooview.el.get_widget()));
 386         var ctr_p= ((Gtk.Container)(this.win.projecteditview.el.get_widget()));
 387
 388         if (file.xtype == "Roo" ) {
 389             ctr.foreach( (w) => { ctr.remove(w); });
 390             ctr_p.foreach( (w) => { ctr_p.remove(w); });
 391             ctr.add(this.window_rooview.el);
 392             ctr_p.add(this.projectsettings.el);
 393             this.window_rooview.loadFile(file);
 394             this.window_rooview.el.show_all();
 395             this.projectsettings.el.show_all();
 396
 397         } else {
 398             ctr.foreach( (w) => { ctr.remove(w); });
 399             ctr_p.foreach( (w) => { ctr_p.remove(w); });
 400             ctr.add(this.window_gladeview.el);
 401             ctr_p.add(this.vala_projectsettings.el);
 402             this.window_gladeview.loadFile(file);
 403             this.window_gladeview.el.show_all();
 404             this.vala_projectsettings.el.show_all();
 405         }
 406         print("OPEN : " + file.name);
 407         this.win.editpane.el.set_position(this.win.editpane.el.max_position);
 408         this.win.setTitle(file.project.name + " : " +file.name);
 409
 410
 411         }
 412
 413
 414     // ---------  webkit view
 415     public void webkitViewInit()
 416     {
 417         this.window_rooview  =new Xcls_WindowRooView();
 418         this.window_rooview.ref();
 419         ((Gtk.Container)(this.win.rooview.el.get_widget())).add(this.window_rooview.el);
 420         this.window_rooview.el.show_all();
 421
 422         var stage = this.win.rooview.el.get_stage();
 423         stage.set_background_color(  Clutter.Color.from_string("#000"));
 424     }
 425
 426     // ------ Gtk  - view
 427
 428     public void gtkViewInit()
 429     {
 430         this.window_gladeview  =new Xcls_GtkView();
 431         this.window_gladeview.ref();
 432     }
 433
 434     public void switchState(State new_state)
 435     {
 436
 437
 438
 439         switch (this.state) {
 440
 441             case State.PREVIEW:
 442                 if (this.left_tree.getActiveFile() != null) {
 443                      if (this.left_tree.getActiveFile().xtype == "Roo" ) {
 444                          this.window_rooview.createThumb();
 445                      } else {
 446                           this.window_gladeview.createThumb();
 447                       }
 448                 }
 449                 // normally we are going from preview to another state.
 450                 // and different windows hide the preview in differnt ways..
 451
 452                 break;
 453
 454            case State.LISTENER:
 455            case State.PROP:
 456                 this.win.addpropsview.el.save_easing_state();
 457                 this.win.addpropsview.el.set_scale(0.0f,0.0f);
 458                 this.win.addpropsview.el.restore_easing_state();
 459                 break;
 460
 461             case State.CODE:
 462
 463
 464                 this.code_editor.saveContents();
 465                 this.win.codeeditview.el.save_easing_state();
 466                 this.win.codeeditview.el.set_scale(0.0f,0.0f);
 467                 this.win.codeeditview.el.restore_easing_state();
 468                 break;
 469
 470
 471              case State.OBJECT:
 472                 this.win.objectview.el.save_easing_state();
 473                 this.win.objectview.el.set_scale(0.0f,0.0f);
 474                 this.win.objectview.el.restore_easing_state();
 475                 break;
 476
 477            case State.PROJECT:
 478                 this.win.projecteditview.el.save_easing_state();
 479                 this.win.projecteditview.el.set_scale(0.0f,0.0f);
 480                 this.win.projecteditview.el.restore_easing_state();
 481                 break;
 482
 483           case State.FILES:
 484                 // hide files...
 485                 this.win.rooview.el.save_easing_state();
 486                 this.win.rooview.el.set_rotation_angle(Clutter.RotateAxis.Y_AXIS, 0.0f);
 487                 this.win.rooview.el.set_scale(1.0f,1.0f);
 488                 this.win.rooview.el.set_pivot_point(0.5f,0.5f);
 489                 this.win.rooview.el.set_opacity(0xff);
 490                 this.win.rooview.el.restore_easing_state();
 491
 492
 493                 this.clutterfiles.el.save_easing_state();
 494                 this.clutterfiles.el.set_easing_duration(1000);
 495                 this.clutterfiles.el.set_pivot_point(0.5f,0.5f);
 496                 this.clutterfiles.el.set_rotation_angle(Clutter.RotateAxis.Y_AXIS, -180.0f);
 497                 this.clutterfiles.el.set_opacity(0);
 498                 this.clutterfiles.el.restore_easing_state();
 499
 500                 //this.clutterfiles.el.hide();
 501
 502
 503                 break;
 504
 505
 506         }
 507
 508         var oldstate  =this.state;
 509         this.state = new_state;
 510
 511
 512         this.buttonsShowHide();
 513
 514         switch (this.state) {
 515
 516             case State.PREVIEW:  // this is the default state when working...
 517                  this.win.editpane.el.show(); // holder for tree and properties..
 518
 519                  this.left_projects.el.hide();
 520
 521
 522                  this.win.rooview.el.save_easing_state();
 523                  this.win.rooview.el.set_scale(1.0f,1.0f);
 524
 525                  this.win.rooview.el.restore_easing_state();
 526
 527                 break;
 528
 529
 530             case State.LISTENER:
 531                 // same as prop?
 532             case State.PROP:
 533                 var ae =      this.left_tree.getActiveElement();
 534                 if (ae == null) {
 535                     this.state = oldstate;
 536                     this.buttonsShowHide();
 537                     return;
 538                 }
 539                 this.add_props.el.show_all();
 540                 this.add_props.show(
 541                     Palete.factory(this.win.project.xtype),
 542                     this.state == State.LISTENER ? "signals" : "props",
 543                     ae.fqn()
 544                 );
 545
 546
 547
 548                 this.win.rooview.el.save_easing_state();
 549                 // -- FIXME? this needs to be State aware?
 550                 this.resizeCanvasElements();
 551                 this.win.rooview.el.restore_easing_state();
 552
 553
 554                 this.win.addpropsview.el.save_easing_state();
 555                 this.win.addpropsview.el.set_scale(1.0f,1.0f);
 556                 this.win.addpropsview.el.restore_easing_state();
 557                 break;
 558
 559             case State.CODE:
 560
 561                 this.code_editor.el.show_all();
 562
 563                 // caller needs to call editor - show....
 564                 this.win.rooview.el.save_easing_state();
 565                 this.resizeCanvasElements();
 566                 this.win.rooview.el.restore_easing_state();
 567
 568
 569                 this.win.codeeditview.el.save_easing_state();
 570                 this.win.codeeditview.el.set_scale(1.0f,1.0f);
 571                 this.win.codeeditview.el.restore_easing_state();
 572                 break;
 573
 574
 575              case State.OBJECT:
 576                  var n = this.left_tree.getActiveElement();
 577
 578                 if (this.left_tree.model.file == null) {
 579                     this.state =oldstate;
 580                     this.buttonsShowHide();
 581                     return;
 582                 }
 583
 584                 if (n == null && this.left_tree.model.file.tree != null) {
 585                     this.state = oldstate;
 586                     this.buttonsShowHide();
 587                     return;
 588                 }
 589
 590                 this.rightpalete.el.show_all();
 591                 this.rightpalete.load(this.left_tree.getActiveFile().palete(), n == null ? "*top" : n.fqn());
 592
 593                 this.win.rooview.el.save_easing_state();
 594                 this.resizeCanvasElements();
 595                 this.win.rooview.el.restore_easing_state();
 596
 597
 598                 this.win.objectview.el.save_easing_state();
 599                 this.win.objectview.el.set_scale(1.0f,1.0f);
 600                 this.win.objectview.el.restore_easing_state();
 601                 break;
 602
 603            case State.PROJECT:
 604
 605              if (this.win.project.xtype == "Roo") {
 606                     this.projectsettings.el.show_all();
 607                     this.projectsettings.show(this.win.project);
 608                 } else {
 609                     this.vala_projectsettings.el.show_all();
 610                     this.vala_projectsettings.show((Project.Gtk)this.win.project);
 611                 }
 612
 613                 this.win.rooview.el.save_easing_state();
 614                 this.resizeCanvasElements();
 615                 this.win.rooview.el.restore_easing_state();
 616
 617                 this.win.projecteditview.el.save_easing_state();
 618                 this.win.projecteditview.el.set_scale(1.0f,1.0f);
 619                 this.win.projecteditview.el.restore_easing_state();
 620                 break;
 621
 622            case State.FILES:  // can only get here from PREVIEW state.. in theory..
 623
 624
 625                 this.win.editpane.el.hide(); // holder for tree and properties..
 626
 627                 this.left_projects.el.show();
 628
 629                 var el = this.win.rooview.el;
 630                 el.save_easing_state();
 631                 el.set_easing_duration(1000);
 632                 el.set_pivot_point(0.5f,0.5f);
 633                 el.set_rotation_angle(Clutter.RotateAxis.Y_AXIS, 180.0f);
 634                 el.set_opacity(0);
 635                 //el.set_scale(0.0f,0.0f);
 636
 637
 638                 if (this.win.project != null) {
 639                     this.left_projects.selectProject(this.win.project);
 640                 }
 641
 642                 el.restore_easing_state();
 643
 644
 645                 this.clutterfiles.el.save_easing_state();
 646                 this.clutterfiles.el.set_easing_duration(1000);
 647                 this.clutterfiles.el.set_pivot_point(0.5f,0.5f);
 648                 this.clutterfiles.el.set_rotation_angle(Clutter.RotateAxis.Y_AXIS, 0.0f);
 649                 this.clutterfiles.el.set_opacity(0xff);
 650                 this.clutterfiles.el.restore_easing_state();
 651
 652
 653                 break;
 654
 655
 656         }
 657
 658
 659     }
 660
 661     // -- buttons show hide.....
 662
 663     public void buttonsShowHide()
 664     {
 665         // basically hide everything, then show the relivant..
 666
 667          this.win.backbutton.el.hide();
 668
 669         this.win.projectbutton.el.hide(); // show file nav...
 670         this.win.editfilebutton.el.hide();
 671         this.win.projecteditbutton.el.hide();
 672
 673
 674         this.win.objectshowbutton.el.hide(); // add objects
 675         this.win.addpropbutton.el.hide();
 676         this.win.addlistenerbutton.el.hide();
 677
 678
 679
 680         this.win.addprojectbutton.el.hide();
 681         this.win.addfilebutton.el.hide();
 682         this.win.delprojectbutton.el.hide();
 683         this.win.new_window.el.hide();
 684
 685
 686         switch (this.state) {
 687
 688             case State.PREVIEW:  // this is the default state when working...
 689
 690                 this.win.projectbutton.el.show(); // show file nav...
 691                 this.win.editfilebutton.el.show();
 692                 this.win.projecteditbutton.el.show();
 693
 694
 695                 this.win.objectshowbutton.el.show(); // add objects
 696                 this.win.addpropbutton.el.show();
 697                 this.win.addlistenerbutton.el.show();
 698                 break;
 699
 700
 701             case State.CODE:
 702             case State.PROP:
 703             case State.LISTENER:
 704             case State.OBJECT:
 705
 706                 this.win.backbutton.el.show();
 707                 this.win.objectshowbutton.el.show(); // add objects
 708                 this.win.addpropbutton.el.show();
 709                 this.win.addlistenerbutton.el.show();
 710                 break;
 711
 712             case State.PROJECT:
 713                 // anything else?
 714                 this.win.backbutton.el.show();
 715                 break;
 716
 717
 718             case State.FILES:
 719                 this.win.backbutton.el.show();
 720
 721                 this.win.addprojectbutton.el.show();
 722                 this.win.addfilebutton.el.show();
 723                 this.win.delprojectbutton.el.show();
 724                 this.win.new_window.el.show();
 725                 break;
 726         }
 727
 728     }
 729
 730     public int redraw_count = 0;
 731     public void resizeCanvas() // called by window resize .. delays redraw
 732     {
 733         var rc = this.redraw_count;
 734         this.redraw_count = 2;
 735         if (rc == 0) {
 736             GLib.Timeout.add(100,  ()  =>{
 737                  return this.resizeCanvasQueue();
 738             });
 739         }
 740     }
 741     public bool  resizeCanvasQueue()
 742     {
 743         //print("WindowState.resizeCanvasQueue %d\n", this.redraw_count);
 744
 745         if (this.redraw_count < 1) {
 746             return false; // should not really happen...
 747         }
 748
 749
 750         this.redraw_count--;
 751
 752         if (this.redraw_count > 0) {
 753             return true; // do it again in 1 second...
 754         }
 755         // got down to 0 or -1....
 756         this.redraw_count = 0;
 757         this.resizeCanvasElements();
 758         return false;
 759
 760     }
 761     public void resizeCanvasElements()
 762     {
 763         Gtk.Allocation alloc;
 764         this.win.clutterembed.el.get_allocation(out alloc);
 765
 766            // print("WindowState.resizeCanvasElements\n");
 767             if (!this.children_loaded || this.win.clutterembed == null) {
 768                 print("WindowState.resizeCanvasElements = ingnore not loaded or no clutterfiles\n");
 769             return;
 770         }
 771             //print("WindowState.resizeCanvasElements = running");
 772
 773
 774         // ------- project view appears at top...
 775
 776
 777         // ------- add property/object left - max 300px, min 50... (or disapear..)
 778
 779         var avail = alloc.width < 50.0f ? 0 :  alloc.width - 50.0f;
 780         var palsize = avail < 300.0f ? avail : 300.0f;
 781         //print("set palsize size %f\n", palsize);
 782         // palate / props : fixed 300 pix
 783
 784
 785         // -------- code edit min 600
 786
 787         var codesize = avail < 800.0f ? avail : 800.0f;
 788         //print("set code size %f\n", codesize);
 789
 790
 791
 792
 793
 794
 795         switch ( this.state) {
 796             case State.PREVIEW:
 797                 this.win.rooview.el.set_size(alloc.width-50, alloc.height);
 798                 break;
 799
 800             case State.FILES:
 801                 this.clutterfiles.set_size(alloc.width-50, alloc.height);
 802                 break;
 803
 804             case State.PROJECT:
 805                 this.win.projecteditview.el.set_size(alloc.width-50, alloc.height / 2.0f);
 806                 break;
 807
 808             case State.CODE:
 809                 this.win.codeeditview.el.set_size(codesize, alloc.height);
 810                 var scale = avail > 0.0f ? (avail - codesize -10 ) / avail : 0.0f;
 811                     this.win.rooview.el.set_scale(scale,scale);
 812                 break;
 813
 814             case State.PROP:
 815             case State.LISTENER:
 816             case State.OBJECT:
 817                 this.win.objectview.el.set_size(palsize, alloc.height);
 818                 this.win.addpropsview.el.set_size(palsize, alloc.height);
 819                     var scale = avail > 0.0f ? (avail - palsize -10 ) / avail : 0.0f;
 820                 this.win.rooview.el.set_scale(scale,scale);
 821                 break;
 822         }
 823     }
 824
 825
 826 }
 827
 828