git.roojs.org Git - roobuilder/blob - src/JsRender/NodeToVala.vala

   1 /**
   2  *
   3  * Code to convert node tree to Vala...
   4  *
   5  * usage : x = (new JsRender.NodeToVala(node)).munge();
   6  *
   7  * Fixmes?
   8  *
   9  *  pack - can we come up with a replacement?
  10      - parent.child == child_widget -- actually uses getters and effectively does 'add'?
  11        (works on most)?
  12
  13
  14  * args  -- vala constructor args (should really only be used at top level - we did use it for clutter originally(
  15  * ctor  -- different ctor argument
  16
  17  *
  18
  19  *
  20  *
  21 */
  22
  23
  24 public abstract class JsRender.NodeToVala : NodeWriter {
  25
  26         protected string this_el = "??";
  27
  28         int child_count = 1; // used to number the children.
  29         public string cls;  // node fqn()
  30         public string xcls;
  31
  32
  33         Gee.ArrayList<string> ignoreWrappedList;
  34         Gee.ArrayList<string> myvars;
  35
  36
  37
  38         int pane_number = 0;// ?? used when generating Gtk.Pane tabs
  39
  40
  41         static construct {
  42                 NodeWriter.globalIgnore("pack");
  43                 NodeWriter.globalIgnore("init");
  44                 NodeWriter.globalIgnore("xns");
  45                 NodeWriter.globalIgnore("xtype");
  46                 NodeWriter.globalIgnore("id");
  47
  48         }
  49         /*
  50          * ctor - just initializes things
  51          * - wraps a render node
  52          */
  53         protected NodeToVala( JsRender file,  Node node,  int depth, NodeToVala? parent)
  54         {
  55
  56                 base (file, node, depth, parent);
  57
  58                 this.initPadding('\t', 1);
  59
  60                 this.cls = node.xvala_cls;
  61                 this.xcls = node.xvala_xcls;
  62                 if (depth == 0 && this.xcls.contains(".")) {
  63                         var ar = this.xcls.split(".");
  64                         this.xcls = ar[ar.length-1];
  65                 }
  66
  67
  68                 this.ignoreWrappedList  = new Gee.ArrayList<string>();
  69                 this.myvars = new Gee.ArrayList<string>();
  70                 this.child_count = 1;
  71
  72         }
  73
  74         public void initCls()
  75         {
  76                 this.cls = this.file.tree.xvala_cls;
  77                 this.xcls = this.file.tree.xvala_xcls;
  78         }
  79         public abstract  string mungeChild(  Node cnode);
  80
  81
  82         public void namespaceHeader()
  83         {
  84                 if (this.depth > 0 || this.file.file_namespace == "") {
  85                         return;
  86                 }
  87                 this.addLine("namespace " + this.file.file_namespace);
  88                 this.addLine("{");
  89
  90         }
  91         public void namespaceFooter()
  92         {
  93                 if (this.depth > 0 || this.file.file_namespace == "") {
  94                         return;
  95                 }
  96                 this.addLine("}");
  97
  98         }
  99
 100
 101         protected abstract void classHeader();
 102
 103
 104
 105         /**
 106          * when ID is used... on an element, it registeres a property on the top level...
 107          * so that _this.ID always works..
 108          *
 109          */
 110         protected void addTopProperties()
 111         {
 112                 if (this.depth > 0) {
 113                         return;
 114                 }
 115                 // properties - global..??
 116                 foreach(var n in this.top_level_items) {
 117
 118                         if (!n.props.has_key("id") || n.xvala_id.length < 0) {
 119                                 continue;
 120
 121                         }
 122                         if (n.xvala_id[0] == '*' || n.xvala_id[0] == '+') {
 123                                 continue;
 124                         }
 125
 126                         this.addLine(this.pad + "public " + n.xvala_xcls + " " + n.xvala_id + ";");
 127
 128                 }
 129
 130         }
 131         /**
 132          * create properties that are not 'part of the wrapped element.
 133          *
 134          *
 135          */
 136
 137         protected void addMyVars()
 138         {
 139                 GLib.debug("callinged addMhyVars");
 140
 141                 this.addLine();
 142                 this.addLine(this.ipad + "// my vars (def)");
 143
 144
 145
 146                 var cls = Palete.Gir.factoryFqn((Project.Gtk) this.file.project, this.node.fqn());
 147
 148                 if (cls == null) {
 149                         GLib.debug("Gir factory failed to find class %s", this.node.fqn());
 150
 151                         //return;
 152                 }
 153
 154
 155                         // Key = TYPE:name
 156                 foreach(var prop in this.node.props.values) {
 157
 158                         if (this.shouldIgnore(prop.name)) {
 159                                 continue;
 160                         }
 161
 162                         // user defined method
 163                         if (prop.ptype == NodePropType.METHOD) {
 164                                 continue;
 165                         }
 166                         if (prop.ptype == NodePropType.SPECIAL) {
 167                                 continue;
 168                         }
 169
 170                         if (prop.ptype == NodePropType.SIGNAL) {
 171                                 this.node.setLine(this.cur_line, "p", prop.name);
 172                                 this.addLine(this.pad + "public signal " + prop.rtype + " " + prop.name  + " "  + prop.val + ";");
 173
 174                                 this.ignore(prop.name);
 175                                 continue;
 176                         }
 177
 178                         GLib.debug("Got myvars: %s", prop.name.strip());
 179
 180                         if (prop.rtype.strip().length < 1) {
 181                                 continue;
 182                         }
 183
 184                         // is it a class property...
 185                         if (cls != null && cls.props.has_key(prop.name) && prop.ptype != NodePropType.USER) {
 186                                 continue;
 187                         }
 188
 189                         this.myvars.add(prop.name);
 190                         prop.start_line = this.cur_line;
 191
 192                         this.node.setLine(this.cur_line, "p", prop.name);
 193
 194                         this.addLine(this.pad + "public " + prop.rtype + " " + prop.name + ";"); // definer - does not include value.
 195
 196
 197                         prop.end_line = this.cur_line;
 198                         this.ignore(prop.name);
 199
 200
 201                 }
 202         }
 203
 204         // if id of child is '+' then it's a property of this..
 205         protected void addPlusProperties()
 206         {
 207                 if (this.node.readItems().size < 1) {
 208                         return;
 209                 }
 210                 var iter = this.node.readItems().list_iterator();
 211                 while (iter.next()) {
 212                         var ci = iter.get();
 213
 214                         if (ci.xvala_id[0] != '+') {
 215                                 continue; // skip generation of children?
 216
 217                         }
 218
 219                         this.addLine(this.pad + "public " + ci.xvala_xcls + " " + ci.xvala_id.substring(1) + ";");
 220
 221
 222                 }
 223         }
 224         /**
 225          * add the constructor definition..
 226          */
 227         protected abstract void addValaCtor();
 228         /**
 229          *  make sure _this is defined..
 230          */
 231         protected void addUnderThis()
 232         {
 233                 // public static?
 234                 if (depth < 1) {
 235                         this.addLine( this.ipad + "_this = this;");
 236                         return;
 237                 }
 238                 // for non top level = _this point to owner, and _this.ID is set
 239
 240                 this.addLine( this.ipad + "_this = _owner;");
 241
 242                 if (this.node.props.has_key("id")
 243                         &&
 244                         this.node.xvala_id != ""
 245                         &&
 246                         this.node.xvala_id[0] != '*'
 247                         &&
 248                         this.node.xvala_id[0] != '+'
 249                         ) {
 250                                 this.addLine( this.ipad + "_this." + node.xvala_id  + " = this;");
 251
 252                 }
 253
 254         }
 255
 256
 257
 258         protected void addInitMyVars()
 259         {
 260                         //var meths = this.palete.getPropertiesFor(item['|xns'] + '.' + item.xtype, 'methods');
 261                         //print(JSON.stringify(meths,null,4));Seed.quit();
 262
 263
 264
 265                         // initialize.. my vars..
 266                 this.addLine();
 267                 this.addLine( this.ipad + "// my vars (dec)");
 268
 269                 var iter = this.myvars.list_iterator();
 270                 while(iter.next()) {
 271
 272                         var k = iter.get();
 273
 274
 275                         var prop = this.node.props.get(k);
 276
 277                         var v = prop.val.strip();
 278
 279                         if (v.length < 1) {
 280                                 continue;
 281                         }
 282                         // at this point start using
 283
 284                         if (v == "FALSE" || v == "TRUE") {
 285                                 v= v.down();
 286                         }
 287                         //FIXME -- check for raw string.. "string XXXX"
 288
 289                         // if it's a string...
 290
 291                         prop.start_line = this.cur_line;
 292                         this.addLine(this.ipad + "this." + prop.name + " = " +   v +";");
 293                         prop.end_line = this.cur_line;
 294                 }
 295         }
 296
 297
 298
 299
 300
 301         protected  void addWrappedProperties()
 302         {
 303                 var cls = Palete.Gir.factoryFqn((Project.Gtk) this.file.project, this.node.fqn());
 304                 if (cls == null) {
 305                         GLib.debug("Skipping wrapped properties - could not find class  %s" , this.node.fqn());
 306                         return;
 307                 }
 308                         // what are the properties of this class???
 309                 this.addLine();
 310                 this.addLine(this.ipad + "// set gobject values");
 311
 312                 foreach(var p in cls.props.keys) {
 313                         var val = cls.props.get(p);
 314                         //print("Check Write %s\n", p);
 315                         if (!this.node.has(p)) {
 316                                 continue;
 317                         }
 318                         if (this.shouldIgnoreWrapped(p)) {
 319                                 continue;
 320                         }
 321
 322                         this.ignore(p);
 323
 324
 325                         var prop = this.node.get_prop(p);
 326                         var v = prop.val;
 327
 328                         // user defined properties.
 329                         if (prop.ptype == NodePropType.USER) {
 330                                 continue;
 331                         }
 332
 333
 334
 335                         var is_raw = prop.ptype == NodePropType.RAW;
 336
 337                         // what's the type.. - if it's a string.. then we quote it..
 338                         if (val.type == "string" && !is_raw) {
 339                                  v = "\"" +  v.escape("") + "\"";
 340                         }
 341                         if (v == "TRUE" || v == "FALSE") {
 342                                 v = v.down();
 343                         }
 344                         if (val.type == "float" && v[v.length-1] != 'f') {
 345                                 v += "f";
 346                         }
 347
 348                         prop.start_line = this.cur_line;
 349                         this.addLine("%s%s%s = %s;".printf(ipad,this.this_el,p,v)); // // %s,  iter.get_value().type);
 350                         prop.end_line = this.cur_line;
 351                            // got a property..
 352
 353
 354                 }
 355         }
 356         /**
 357          *  pack the children into the parent.
 358          *
 359          * if the child's id starts with '*' then it is not packed...
 360          * - this allows you to define children and add them manually..
 361          */
 362
 363         protected  void addChildren()
 364         {
 365                                 //code
 366                 if (this.node.readItems().size < 1) {
 367                         return;
 368                 }
 369                 this.pane_number = 0;
 370                 var cols = this.node.has("* columns") ? int.max(1, int.parse(this.node.get_prop("* columns").val)) : 1;
 371                 var colpos = 0;
 372
 373
 374
 375                 foreach(var child in this.node.readItems()) {
 376
 377
 378
 379
 380                         if (child.xvala_id[0] == '*') {
 381                                 continue; // skip generation of children?
 382                         }
 383
 384                         // probably added in ctor..
 385                         if (child.has("* prop") && this.shouldIgnoreWrapped(child.get_prop("* prop").val)) {
 386                                 continue;
 387                         }
 388                         // create the element..
 389
 390                         // this is only needed if it does not have an ID???
 391                         var childname = this.addPropSet(child, child.has("id") ? child.get_prop("id").val : "") ;
 392
 393                         if (child.has("* prop")) {
 394
 395
 396                                 // fixme special packing!??!?!
 397                                 if (child.get_prop("* prop").val.contains("[]")) {
 398                                         // currently these 'child props
 399                                         // used for label[]  on Notebook
 400                                         // used for button[]  on Dialog?
 401                                         // columns[] ?
 402
 403                                         this.packChild(child, childname, 0, 0, child.get_prop("* prop").val);  /// fixme - this is a bit speciall...
 404                                         continue;
 405                                 }
 406
 407
 408
 409                                 this.ignoreWrapped(child.get_prop("* prop").val);
 410                                 var el_name = this.this_el == "this.el." ? ".el" : "";
 411                                 this.addLine(ipad + this.this_el  + child.get_prop("* prop").val + " = " + childname + el_name +";");
 412
 413                                 continue;
 414                         }
 415                          if (!child.has("id") && this.this_el == "this.el.") {
 416                                 this.addLine(this.ipad +  childname +".ref();");
 417                          }
 418                         this.packChild(child, childname, cols, colpos);
 419
 420                         if (child.has("colspan")) {
 421                                 colpos += int.parse(child.get_prop("colspan").val);
 422                         } else {
 423                                 colpos += 1;
 424                         }
 425
 426
 427                         // this.{id - without the '+'} = the element...
 428
 429
 430                 }
 431         }
 432
 433         protected string addPropSet(Node child, string child_name)
 434         {
 435
 436
 437                 var xargs = "";
 438                 if (child.has("* args")) {
 439
 440                         var ar = child.get_prop("* args").val.split(",");
 441                         for (var ari = 0 ; ari < ar.length; ari++ ) {
 442                                 var arg = ar[ari].split(" ");
 443                                 xargs += "," + arg[arg.length -1];
 444                         }
 445                 }
 446
 447                 var childname = "child_" + "%d".printf(this.child_count++);
 448                 var prefix = "";
 449                 if (child_name == "") {
 450                         prefix = "var " + childname + " = ";
 451                 }
 452                 var cls =  child.xvala_xcls;
 453                 /*
 454                 if (this.this_el == "this.") {
 455                         var clsdata = Palete.Gir.factoryFqn((Project.Gtk) this.file.project, this.node.fqn());
 456                         //if (clsdata.is_sealed) {
 457                                 cls = this.node.fqn(); // need ctor data...
 458                                 this.addLine(this.ipad + @"$(prefix)new $cls( _this $xargs);" );
 459                                 return child_name == "" ? childname : ("_this." + child_name);
 460                         }
 461                 }
 462                 */
 463
 464                 this.addLine(this.ipad + @"$(prefix)new $cls( _this $xargs);" );
 465
 466                 // add a ref... (if 'id' is not set... to a '+' ?? what does that mean? - fake ids?
 467                 // remove '+' support as I cant remember what it does!!!
 468                 //if (child.xvala_id.length < 1 ) {
 469                 //      this.addLine(this.ipad + childname +".ref();"); // we need to reference increase unnamed children...
 470                 //}
 471             //if (child.xvala_id[0] == '+') {
 472                 //      this.addLine(this.ipad + "this." + child.xvala_id.substring(1) + " = " + childname+  ";");
 473
 474                 //}
 475
 476
 477                 return child_name == "" ? childname : ("_this." + child_name);
 478         }
 479
 480
 481
 482
 483         protected void packChild(Node child, string childname, int cols, int colpos, string propname= "")
 484         {
 485
 486                 GLib.debug("packChild %s=>%s", this.node.fqn(), child.fqn());
 487                 // forcing no packing? - true or false? -should we just accept false?
 488                 if (child.has("* pack") && child.get("* pack").down() == "false") {
 489                         return; // force no packing
 490                 }
 491                 if (child.has("* pack") && child.get("* pack").down() == "true") {
 492                         return; // force no packing
 493                 }
 494                 var el_name = this.this_el == "this.el." ? ".el" : "";
 495                 var this_el = this.this_el;
 496                 // BC really - don't want to support this anymore.
 497                 if (child.has("* pack")) {
 498
 499                         string[]  packing =  { "add" };
 500                         if (child.has("* pack")) {
 501                                 packing = child.get("* pack").split(",");
 502                         }
 503
 504                         var pack = packing[0];
 505                         this.addLine(this.ipad + this.this_el + pack.strip() + " ( " + childname + el_name + " " +
 506                                    (packing.length > 1 ?
 507                                                 (", " + string.joinv(",", packing).substring(pack.length+1))
 508                                         : "" ) + " );");
 509                         return;
 510                 }
 511                 var childcls =  this.file.project.palete.getClass(child.fqn()); // very trusting..
 512                 if (childcls == null) {
 513                   return;
 514                 }
 515                 // GTK4
 516                 var is_event = childcls.inherits.contains("Gtk.EventController") || childcls.implements.contains("Gtk.EventController");
 517                 if (is_event) {
 518                     this.addLine(this.ipad + this.this_el + "add_controller(  %s.el );".printf(childname) );
 519                     return;
 520                 }
 521
 522
 523                 switch (this.node.fqn()) {
 524
 525
 526
 527                         case "Gtk.Fixed":
 528                         case "Gtk.Layout":
 529                                 var x = child.has("x") ?  child.get_prop("x").val  : "0";
 530                                 var y = child.has("y") ?  child.get_prop("y").val  : "0";
 531                                 this.addLine(@"$(ipad)$(this_el)put( $(childname)$(el_name), $(x), $(y) );");
 532                                 return;
 533
 534
 535
 536                         case "Gtk.Stack":
 537                                 var named = child.has("stack_name") ?  child.get_prop("stack_name").val.escape() : "";
 538                                 var title = child.has("stack_title") ?  child.get_prop("stack_title").val.escape()  : "";
 539                                 if (title.length > 0) {
 540                                         this.addLine(@"$(ipad)$(this_el)add_titled( $(childname)$(el_name), \"$(named)\", \"$(title)\" );");
 541                                         return;
 542                                 }
 543                                 this.addLine(@"$(ipad)$(this_el)add_named( $(childname)$(el_name), \"$(named)\");");
 544                                 return;
 545
 546                         case "Gtk.Notebook": // use label
 547                                 var label = child.has("notebook_label") ?  child.get_prop("notebook_label").val.escape() : "";
 548                                 this.addLine(@"$(ipad)$(this_el)append_page( $(childname)$(el_name), new Gtk.Label(\"$(label)\");");
 549
 550                                 return;
 551
 552
 553                         case "Gtk.TreeView": // adding TreeViewColumns
 554                                 this.addLine(this.ipad + "this.el.append_column( " + childname + ".el );");
 555                                 return;
 556
 557                         case "Gtk.TreeViewColumn": //adding Renderers - I think these are all proprerties of the renderer used...
 558                                 if (child.has("markup_column") && int.parse(child.get_prop("markup_column").val) > -1) {
 559                                         var val = child.get_prop("markup_column").val;
 560                                         this.addLine(@"$(ipad)$(this_el)add_attribute( $(childname)$(el_name), \"markup\", $(val) );");
 561
 562                                 }
 563                                 if (child.has("text_column") && int.parse(child.get_prop("text_column").val) > -1) {
 564                                         var val = child.get_prop("text_column").val;
 565                                         this.addLine(@"$(ipad)$(this_el)add_attribute( $(childname)$(el_name), \"text\", $(val) );");
 566                                 }
 567                                 if (child.has("pixbuf_column") && int.parse(child.get_prop("pixbuf_column").val) > -1) {
 568                                         var val = child.get_prop("pixbuf_column").val;
 569                                         this.addLine(@"$(ipad)$(this_el).add_attribute( $(childname)$(el_name), \"pixbuf\", $(val) );");
 570                                 }
 571                                 if (child.has("pixbuf_column") && int.parse(child.get_prop("active_column").val) > -1) {
 572                                         var val = child.get_prop("active_column").val;
 573                                         this.addLine(@"$(ipad)$(this_el).add_attribute( $(childname)$(el_name), \"active\", $(val) );");
 574                                 }
 575                                 if (child.has("background_column") && int.parse(child.get_prop("background_column").val) > -1) {
 576                                 var val = child.get_prop("background_column").val;
 577                                         this.addLine(@"$(ipad)$(this_el).add_attribute( $(childname)$(el_name), \"background-rgba\", $(val) );");
 578                                 }
 579                                 this.addLine(this.ipad + "this.el.add( " + childname + ".el );");
 580                                 // any more!?
 581                                 return;
 582
 583                         case "Gtk.Dialog":
 584                                 if (propname == "buttons[]") {
 585                                         var resp_id = int.parse(childname.replace("child_", ""));
 586                                         if (child.has("* response_id")) {
 587                                                 resp_id = int.parse(child.get_prop("* response_id").val);
 588                                         }
 589                                         this.addLine(@"$(ipad)$(this_el).add_action_widget( $(childname)$(el_name), $(resp_id) );");
 590
 591                                         return;
 592                                 }
 593
 594                                 this.addLine(@"$(ipad)$$(this_el)get_content_area().add( $(childname)$(el_name) );");
 595                                 return;
 596
 597
 598
 599
 600
 601
 602         // known working with GTK4 !
 603                         case "Gtk.HeaderBar": // it could be end... - not sure how to hanle that other than overriding                                  this.addLine(this.ipad + "this.el.add_action_widget( %s.el, %d);".printf(childname,resp_id) ); the pack method?
 604                                 this.addLine(@"$(ipad)$(this_el)pack_start( $(childname)$(el_name) );");
 605                                 return;
 606
 607                         case "GLib.Menu":
 608                                 this.addLine(@"$(ipad)$(this_el)append_item( $(childname)$(el_name) );");
 609                                 return;
 610
 611                         case "Gtk.Paned":
 612                                 this.pane_number++;
 613                                 switch(this.pane_number) {
 614                                         case 1:
 615                                                 this.addLine(@"$(ipad)$(this_el)pack_start( $(childname)$(el_name) );");
 616                                                 return;
 617                                         case 2:
 618                                                 this.addLine(@"$(ipad)$(this_el)pack_end( $(childname)$(el_name) );");
 619                                                 return;
 620                                         default:
 621                                                 // do nothing
 622                                                 break;
 623                                 }
 624                                 return;
 625
 626                         case "Gtk.ColumnView":
 627                                 this.addLine(@"$(ipad)$(this_el)append_column( $(childname)$(el_name) );");
 628                                 return;
 629
 630                         case "Gtk.Grid":
 631                                 var x = "%d".printf(colpos % cols);
 632                                 var y = "%d".printf(( colpos - (colpos % cols) ) / cols);
 633                                 var w = child.has("colspan") ? child.get_prop("colspan").val : "1";
 634                                 var h = "1";
 635                                 this.addLine(@"$(ipad)$(this_el)attach( $(childname)$(el_name), $x, $y, $w, $h );");
 636                                 return;
 637
 638                         default:
 639                                 this.addLine(@"$(ipad)$(this_el)append( $(childname)$(el_name) );");
 640                             // gtk4 uses append!!!! - gtk3 - uses add..
 641                                 return;
 642
 643
 644                 }
 645
 646
 647         }
 648
 649         // fixme GtkDialog?!? buttons[]
 650
 651         // fixme ... add case "Gtk.RadioButton":  // group_id ??
 652
 653
 654
 655         protected void addInit()
 656         {
 657
 658
 659                 if (!this.node.has("* init")) {
 660                                 return;
 661                 }
 662                 this.addLine();
 663                 this.addLine(ipad + "// init method");
 664                 this.addLine();
 665                 this.node.setLine(this.cur_line, "p", "init");
 666
 667                 var init =  this.node.get_prop("* init");
 668                 init.start_line = this.cur_line;
 669                 this.addMultiLine(ipad + this.padMultiline(ipad, init.val) );
 670                 init.end_line = this.cur_line;
 671          }
 672          protected void addListeners()
 673          {
 674                 if (this.node.listeners.size < 1) {
 675                         return;
 676                 }
 677
 678                 this.addLine();
 679                 this.addLine(ipad + "//listeners");
 680
 681
 682
 683                 var iter = this.node.listeners.map_iterator();
 684                 while (iter.next()) {
 685                         var k = iter.get_key();
 686                         var prop = iter.get_value();
 687                         var v = prop.val;
 688
 689                         prop.start_line = this.cur_line;
 690                         this.node.setLine(this.cur_line, "l", k);
 691                         this.addMultiLine(this.ipad + this.this_el + k + ".connect( " +
 692                                         this.padMultiline(this.ipad,v) +");");
 693                         prop.end_line = this.cur_line;
 694                 }
 695         }
 696         protected void addEndCtor()
 697         {
 698
 699                         // end ctor..
 700                         this.addLine(this.pad + "}");
 701         }
 702
 703
 704         /*
 705  * Standardize this crap...
 706  *
 707  * standard properties (use to set)
 708  *          If they are long values show the dialog..
 709  *
 710  * someprop : ....
 711  * bool is_xxx  :: can show a pulldown.. (true/false)
 712  * string html
 713  * $ string html  = string with value interpolated eg. baseURL + ".."
 714  *  Clutter.ActorAlign x_align  (typed)  -- shows pulldowns if type is ENUM?
 715  * $ untypedvalue = javascript untyped value...
 716  * _ string html ... = translatable..
 717
 718  *
 719  * object properties (not part of the GOjbect being wrapped?
 720  * # Gee.ArrayList<Xcls_fileitem> fileitems
 721  *
 722  * signals
 723  * @ void open
 724  *
 725  * methods -- always text editor..
 726  * | void clearFiles
 727  * | someJSmethod
 728  *
 729  * specials
 730  * * prop -- string
 731  * * args  -- string
 732  * * ctor -- string
 733  * * init -- big string?
 734  *
 735  * event handlers (listeners)
 736  *   just shown
 737  *
 738  * -----------------
 739  * special ID values
 740  *  +XXXX -- indicates it's a instance property / not glob...
 741  *  *XXXX -- skip writing glob property (used as classes that can be created...)
 742  *
 743  *
 744  */
 745
 746         protected void addUserMethods()
 747         {
 748                 this.addLine();
 749                 this.addLine(this.pad + "// user defined functions");
 750
 751                         // user defined functions...
 752                 var iter = this.node.props.map_iterator();
 753                 while(iter.next()) {
 754                         var prop = iter.get_value();
 755                         if (this.shouldIgnore(prop.name)) {
 756                                 continue;
 757                         }
 758                         // HOW TO DETERIME if its a method?
 759                         if (prop.ptype != NodePropType.METHOD) {
 760                                         //strbuilder("\n" + pad + "// skip " + k + " - not pipe \n");
 761                                         continue;
 762                         }
 763
 764                         // function in the format of {type} (args) { .... }
 765
 766
 767
 768                         prop.start_line = this.cur_line;
 769                         this.node.setLine(this.cur_line, "p", prop.name);
 770                         this.addMultiLine(this.pad + "public " + prop.rtype + " " +  prop.name + " " + this.padMultiline(this.pad, prop.val));;
 771                         prop.end_line = this.cur_line;
 772
 773                 }
 774         }
 775
 776         protected void iterChildren()
 777         {
 778                 this.node.line_end = this.cur_line;
 779                 this.node.sortLines();
 780
 781
 782                 if (this.depth > 0) {
 783                         this.addLine(this.inpad + "}");
 784                 }
 785
 786                 var iter = this.node.readItems().list_iterator();
 787
 788                 while (iter.next()) {
 789                         this.addMultiLine(this.mungeChild(iter.get()));
 790                 }
 791
 792                 if (this.depth < 1) {
 793                         this.addLine(this.inpad + "}");
 794                 }
 795
 796         }
 797
 798
 799
 800         protected void ignoreWrapped(string i) {
 801                 this.ignoreWrappedList.add(i);
 802
 803         }
 804
 805         protected  bool shouldIgnoreWrapped(string i)
 806         {
 807                 return ignoreWrappedList.contains(i);
 808         }
 809
 810 }
 811
 812
 813
 814