git.roojs.org Git - app.mailtrimmer/blob - src/strip.vala

   1 /**
   2
   3  ** check left to do:
   4   - range scans on maildir
   5   - see how replacing the links works in the resulting email via thunderbird etc..
   6   - some checksum issues (see dupelicates?? suspect 0byte issues?)  -- seems ok now?
   7
   8
   9
  10
  11   needs to scan 2 things
  12   a) our mailfort email database
  13        point it at the top directory, containing YEAR/MONTH/DAY.... directories.
  14        scan each file (over a year old...)
  15        extract out the attachment, and replace with HTML
  16        DATABASE? - mysql or sqlite? -
  17            filesize / name / date / checksum / mimetype -- into mailfort should be OK.
  18   b) the imap user emails
  19            loop through user's directories
  20            check age of email .. over 1 years..
  21            ?? how to prevent 'repeat' scanning of emails?
  22               ??? hidden '.' files containing last scan date?
  23
  24            check if file exists in our DB.. - replace the link...
  25            otherwise generate a file. + add to DB...
  26
  27    c) retreival system
  28      -> URL -> get file
  29    d) redirect system.
  30      -> URL -> redirect to correct server
  31
  32
  33 More notes on our Mailfort DB sync:
  34 * some of these attachments are already in the database...
  35  - so we need to update the DB..
  36  - probably worth putting the code in a stored procedure..
  37
  38  -- key scenarios
  39    * first scan (and extract)
  40    * rescan (as I messed up the first time - fix the DB...)
  41    * email scan - attachments might not have related messages.
  42
  43
  44  - {id} attachment_init(
  45                 {exim_msg_id}
  46                 {chksum}
  47                 {filename),
  48         )
  49         // creates or returns id (can look for existing messages?
  50         // can do a merge?? - copy 'old' record data into 'new'....  "prefer checksummed"
  51
  52         attachment_update(
  53                 {id}
  54                 {exim_msg_id}
  55                 {mailfort_msg_sig}
  56                 {file_size}
  57                 {created} // message date..
  58                 {chksum}
  59                 {filename),
  60         {mime_type}
  61         )
  62         attachment_update_store(
  63                         {id}
  64                         {stored_filename}
  65         )
  66
  67
  68 */
  69
  70 // valac --pkg gmime --vapi
  71 /*
  72
  73 // http://www.fromdual.com/mysql-vala-program-example << check mysql if this does not work.
  74
  75  valac  -g --vapidir=. --thread  strip.vala   --vapidir=../vapi \
  76      --pkg glib-2.0 --pkg mysql --pkg gio-2.0 --pkg posix --pkg gmime-2.6 \
  77       --Xcc=-lmysqlclient  -v \
  78        -o /tmp/strip
  79 */
  80
  81 public class StripApplication : GLib.Application {
  82
  83         public static string? opt_path = null;
  84         public static string? opt_file = null;
  85         public static string? opt_target_path = null;
  86         public static string? opt_db_host = "127.0.0.1";
  87         public static string? opt_db_name = null;
  88         public static string? opt_db_user = null;
  89         public static string? opt_db_pass = null;
  90
  91         public static int    opt_limit = -1;
  92
  93         public static int    opt_age_newest = 1;
  94         public static int    opt_age_oldest = 6;
  95
  96
  97         public static bool      opt_is_extracting = false;
  98         public static bool      opt_is_replacing = false;
  99         public static bool      opt_scan_maildir  = false;
 100         public static bool      opt_scan_mailfort  = false;
 101         public static bool              opt_dump = false;
 102         public static bool              opt_debug = false;
 103
 104         public static bool opt_debug_sql = false;
 105         public static string? opt_replace_link = null;
 106
 107
 108         public const GLib.OptionEntry[] options = {
 109
 110                 { "debug", 0, 0, OptionArg.NONE, ref opt_debug, "show debug messages for components", null },
 111                 { "debug-sql", 0, 0, OptionArg.NONE, ref opt_debug_sql, "debug the SQL statements", null },
 112
 113                 { "path", 0, 0, OptionArg.STRING, ref opt_path, "Directory where email to be parsed is", null },
 114                 { "file", 0, 0, OptionArg.STRING, ref opt_file, "A specific file to be parsed", null },
 115
 116                 { "target-path", 0, 0, OptionArg.STRING, ref opt_target_path, "Directory where attachments are to be put", null },
 117
 118                 { "link", 0, 0, OptionArg.STRING, ref opt_replace_link, "url for the replement link: eg. http://www.mysite.com/xxxx/%s", null },
 119
 120                 { "host", 0, 0, OptionArg.STRING, ref opt_db_host, "Mysql host (default localhost)", null },
 121                 { "name", 0, 0, OptionArg.STRING, ref opt_db_name, "Mysql database name REQUIRED", null },
 122                 { "user", 0, 0, OptionArg.STRING, ref opt_db_user, "Mysql database user REQUIRED", null },
 123                 { "pass", 0, 0, OptionArg.STRING, ref opt_db_pass, "Mysql database password (default empty)", null },
 124
 125                 { "extract", 0, 0, OptionArg.NONE, ref opt_is_extracting, "Should attachments be extracted (default NO)", null },
 126                 { "replace", 0, 0, OptionArg.NONE, ref opt_is_replacing, "Should attachments be replaced (default NO)", null },
 127                 { "dump", 0, 0, OptionArg.NONE, ref opt_dump, "Print the replaced mail contents to stdout", null },
 128
 129                 { "limit", 0, 0, OptionArg.INT, ref opt_limit, "stop after X number of messages with attachments have been processed", null },
 130                 { "newest", 0, 0, OptionArg.INT, ref opt_age_newest, "do not replace messages newer that X months (default is 1 months)", null },
 131                 { "oldest", 0, 0, OptionArg.INT, ref opt_age_oldest, "do not replace messages older than X (default is 6 months)", null },
 132
 133                 { "scan-maildir", 0, 0, OptionArg.NONE, ref opt_scan_maildir, "scan an maildir tree", null },
 134                 { "scan-mailfort", 0, 0, OptionArg.NONE, ref opt_scan_mailfort, "scan a mailfort tree", null },
 135                 { null }
 136         };
 137     public StripApplication( string[] args )
 138     {
 139                  Object(
 140             application_id: "org.roojs.mailstripper",
 141             flags: ApplicationFlags.FLAGS_NONE
 142          );
 143
 144
 145          var opt_context =  new GLib.OptionContext ("Mail Stripper");
 146
 147          try {
 148
 149             opt_context.set_help_enabled (true);
 150             opt_context.add_main_entries (options, null);
 151             opt_context.parse ( ref  args);
 152             //opt_detach = !optx_no_detach;
 153
 154
 155
 156              // options that have to be set.. bee or hive... (or stop all)
 157             if ((!opt_scan_mailfort && !opt_scan_maildir) || (opt_scan_mailfort && opt_scan_maildir))  {
 158                stdout.printf ("You must specify the type of directory tree to scan - either imap or mailfort\n%s",
 159                    opt_context.get_help(true, null));
 160                GLib.Process.exit(Posix.EXIT_FAILURE);
 161             }
 162
 163                          if ((opt_db_name == null || opt_db_name.length < 1 || opt_db_user == null || opt_db_user.length < 1))  {
 164                stdout.printf ("You must specify the database name / user \n%s",
 165                    opt_context.get_help(true, null));
 166                GLib.Process.exit(Posix.EXIT_FAILURE);
 167             }
 168                          if ((opt_path == null || opt_path.length < 1)   )  {
 169                stdout.printf ("You must specify the scan start path\n%s",
 170                    opt_context.get_help(true, null));
 171                GLib.Process.exit(Posix.EXIT_FAILURE);
 172             }
 173                         if (opt_replace_link == null || (opt_replace_link.length < 1))  {
 174                stdout.printf ("You must specify the link to use in the replacement \n%s",
 175                    opt_context.get_help(true, null));
 176                GLib.Process.exit(Posix.EXIT_FAILURE);
 177             }
 178             if ((opt_is_replacing || opt_is_extracting ) && (opt_target_path == null || opt_target_path.length < 1)) {
 179                       stdout.printf ("You must specify a target path to put attachments\n%s",
 180                    opt_context.get_help(true, null));
 181                GLib.Process.exit(Posix.EXIT_FAILURE);
 182             }
 183
 184
 185          } catch (GLib.OptionError e) {
 186             stdout.printf ("error: %s\n", e.message);
 187             stdout.printf ("Run '%s --help' to see a full list of available command line options.\n%s",
 188                       args[0], opt_context.get_help(true, null));
 189             GLib.Process.exit(Posix.EXIT_FAILURE);
 190          }
 191         }
 192
 193     public static int main(string[] args)
 194     {
 195
 196                 var application = new StripApplication(  args);
 197
 198                 GLib.Log.set_always_fatal(LogLevelFlags.LEVEL_ERROR | LogLevelFlags.LEVEL_CRITICAL);
 199
 200            if (opt_debug || opt_debug_sql) {
 201                         GLib.Log.set_handler(null,
 202                         GLib.LogLevelFlags.LEVEL_DEBUG | GLib.LogLevelFlags.LEVEL_WARNING | GLib.LogLevelFlags.LEVEL_INFO,
 203                         (dom, lvl, msg) => {
 204                                         print("%s\n", msg);
 205                                 }
 206                         );
 207                 }
 208
 209         GMime.init(0);
 210                 if (StripApplication.opt_is_replacing) {
 211                         StripApplication.opt_is_extracting = true;
 212                 }
 213
 214                 GLib.debug("scanning folder: %s", opt_path );
 215
 216                 var strip = new Strip( opt_path );
 217
 218
 219                 strip.mysql  = new Mysql.Database();
 220                 if (!strip.mysql.real_connect(
 221                                 opt_db_host,
 222                                 opt_db_user ,
 223                                 opt_db_pass == null ? "" : opt_db_pass, //passwd
 224                                 opt_db_name, //DB
 225                                 3306, // not changable...?
 226                                 null
 227                         )
 228                 ) {
 229                         stdout.printf("ERROR %u: Connection failed: %s\n",
 230                                 strip.mysql.errno(), strip.mysql.error()
 231                         );
 232
 233                         return 1;
 234                 }
 235         if (opt_file != null) {
 236                 strip.base_dir = opt_path;
 237                 strip.scan_file( GLib.Path.get_dirname(opt_file),  GLib.Path.get_basename(opt_file));
 238                 return 0;
 239         }
 240
 241                 strip.scan_dir(opt_path, "");
 242
 243
 244
 245         return 0;
 246     }
 247 }
 248
 249 public class Strip : GLib.Object {
 250
 251
 252
 253         public string base_dir = "";
 254
 255         public Mysql.Database mysql;
 256
 257         int processed = 0;
 258
 259     uint64 used_space_before = 0;
 260     uint64 used_space_after = 0;
 261
 262
 263     public Strip(string base_dir)
 264     {
 265         this.base_dir = base_dir;
 266     }
 267
 268     public void handle_part(GMime.Object parent, GMime.Object mime_obj)
 269     {
 270                 if (mime_obj is GMime.Part) {
 271                    var  p = (GMime.Part)mime_obj;
 272                         var ct = p.get_content_type();
 273                         var cd = p.get_content_disposition();
 274
 275                         var sid = p.get_header("X-strip-id");
 276                     if (sid != null && sid.length > 0) {
 277                         this.update_attachment_db(p);
 278                             GLib.debug("Skip attachment replace - it's already been done");
 279                         return;
 280                         }
 281
 282                         if (cd == null || cd.get_disposition().down() != "attachment") {
 283                                 return;
 284                         }
 285                         if (ct.get_media_type() == "text") {
 286                                 return;
 287                         }
 288                         if (ct.to_string() == "application/pgp-encrypted") {
 289                                 return;
 290                         }
 291                         if (ct.to_string() == "application/pgp-keys") {
 292                                 return;
 293                         }
 294                         if (p.get_filename() == null) {
 295                                 return;
 296                         }
 297                          // print("got part %s\n", ct.to_string());
 298                          if (parent is GMime.Multipart) {
 299
 300                                 this.replace_attachment(((GMime.Multipart)parent), p);
 301                                 // remove it !?
 302
 303                           }
 304
 305
 306                         return;
 307                 }
 308                 if (mime_obj is GMime.Multipart) {
 309
 310
 311                         var  mp = (GMime.Multipart)mime_obj;
 312                         //var ct = mp.get_content_type();
 313
 314                         //print("got multi-part %s\n", ct.to_string());
 315                         for (var i = 0; i< mp.get_count(); i++) {
 316                           var mo = mp.get_part(i);
 317                           this.handle_part(mime_obj,mo);
 318                         }
 319                    // ((GMime.Multipart)mime_obj).foreach((sub_obj) => {
 320                    //     Strip.handle_part(sub_obj);
 321                 //
 322                    // });
 323
 324
 325                         return;
 326                 }
 327
 328                 if (mime_obj is GMime.MessagePart) {
 329                         var msg = ((GMime.MessagePart)mime_obj).get_message();
 330                         msg.foreach((subobj) => {
 331                          this.handle_part(msg,subobj);
 332                     });
 333
 334                         //print("got message-part\n");
 335                         return;
 336                 }
 337
 338                 if (mime_obj is GMime.Message) {
 339                         var mp = ((GMime.Message) mime_obj).get_mime_part();
 340
 341                         if (!(mp is GMime.Multipart)) {
 342                                 //GLib.debug("get mimepart does not return a Multipart?");
 343                                 return;
 344                         }
 345
 346                         var mpc = ((GMime.Multipart)mp).get_count();
 347
 348                         //GLib.debug("Message has %d parts", mpc);
 349                         for (var i =0 ; i < mpc; i++) {
 350                                 //GLib.debug("Getting part %d", i);
 351                                 var submime_obj = ((GMime.Multipart)mp).get_part(i);
 352                         this.handle_part(mp,submime_obj);
 353                     }
 354                         print("got message??\n");
 355                         return;
 356                 }
 357
 358                 print("got something else\n");
 359
 360
 361     }
 362     public void update_attachment_db(GMime.Part attachment)
 363     {
 364         // only called when we have an sid...
 365         var sid = attachment.get_header("X-strip-id");
 366         if (sid == null || sid.length < 1) {
 367                 GLib.debug("Strange - update attachment db called ?");
 368                 return;
 369         }
 370
 371         // initialize it with known data..
 372         // that should wipe out dupes.
 373         var matches = this.execute("SELECT count(id) as nid FROM Attachment WHERE id = %d".printf(
 374                         int.parse(sid)));
 375
 376
 377                 if (matches=="") {
 378                         // our old mailfort code deleted the crap out of old records...
 379                         // if this occurs we will need to create the record again..
 380                    GLib.error("Failed to find id  :%s", sid);
 381                    return;
 382                 }
 383
 384
 385         // initialize it with known data..
 386         // that should wipe out dupes.
 387         var filesize = this.execute("SELECT filesize FROM Attachment WHERE id = %d".printf(
 388                         int.parse(sid)));
 389
 390                 if (filesize=="") {
 391                    GLib.debug("Ignoring record id (missing in database) :%s", sid);
 392                    return;
 393                 }
 394                 if (int.parse(filesize) < 1) {
 395                 GLib.debug("Could not get filesize from id :%s = %s", sid,filesize);
 396                 Posix.exit(0);
 397                 return;
 398         }
 399
 400         var chksum = this.query("SELECT  checksum FROM Attachment WHERE id = %d".printf(
 401                         int.parse(sid)
 402                 ));
 403         var mime_filename = this.query("SELECT  mime_filename FROM Attachment WHERE id = %d".printf(
 404                         int.parse(sid)));
 405
 406         this.query("""
 407              SELECT
 408                  attachment_init(
 409                      '%s', '%s', '%s', %d
 410                  ) as id
 411
 412           """.printf(
 413                           this.mysql_escape(this.active_message_exim_id),
 414                           this.mysql_escape(chksum),
 415                           this.mysql_escape(mime_filename),
 416                           int.parse(filesize)
 417                 ));
 418         this.query("""
 419                  SELECT attachment_update(
 420                       %d, -- in_id INT(11),
 421                       '%s', -- in_mime_type varchar(255),
 422                       '%s', -- in_created DATETIME,
 423                       '%s' -- in_mailfort_sig varchar(64)
 424                  )
 425               """.printf(
 426                         int.parse(sid),
 427                         "", // this will be ignored..
 428                                 this.created_date,
 429                                 this.mysql_escape(this.active_message_x_mailfort_sig)
 430
 431               )
 432                 );
 433                 this.mysql.store_result();
 434
 435
 436
 437     }
 438
 439
 440     public void replace_attachment(GMime.Multipart parent, GMime.Part attachment)
 441     {
 442         var sid = attachment.get_header("X-strip-id");
 443         if (sid != null && sid.length > 0) {
 444                 GLib.debug("Skip attachment replace - it's already been done");
 445                 return;
 446         }
 447
 448         var c = attachment.get_content_object();
 449
 450         var filename = attachment.get_filename().replace("/", "-").replace("\n", "").replace("\t", " ");
 451         var fn = GLib.Environment.get_tmp_dir() +
 452                         "/"+ this.active_name + "."+   filename;
 453
 454             var outfile = new GMime.StreamFile.for_path(fn, "w");
 455             outfile.set_owner(true);
 456             var file_size = (int) c.write_to_stream(outfile);
 457             var chksum = this.md5_file(fn);
 458             outfile.flush();
 459             outfile = null;
 460
 461         if (file_size == 0) {
 462
 463                 GLib.debug("ERROR - file size of write to stream returned 0?");
 464                 Posix.unlink(fn);
 465                 return;
 466         }
 467
 468
 469
 470
 471         var mime_type= attachment.get_content_type().to_string();
 472         // at this point we have to do our database magic...
 473         //filesize / name / date / checksum / mimetype -- into mailfort should be OK.
 474
 475         var file_id = this.query("""
 476                 SELECT
 477
 478                 attachment_init(
 479                                 '%s', -- in_msgid VARCHAR(32),
 480                                 '%s', -- in_checksum VARCHAR(64),
 481                                 '%s', -- in_mime_filename varchar(255)
 482                                 %d -- filesize
 483                         ) as id
 484
 485           """.printf(
 486                         this.mysql_escape(this.active_message_exim_id),
 487                         chksum,
 488                         this.mysql_escape( attachment.get_filename() ), // what is thsi is invalid?
 489                          file_size)
 490                 );
 491
 492
 493                 if (file_id.length < 1) {
 494                         GLib.debug("ERROR - CALL to attachment_init failed");
 495                 Posix.unlink(fn);
 496                 return;
 497
 498                 }
 499
 500                 if (int.parse(file_id) < 1) {
 501                         GLib.debug("ERROR - CALL to attachment_init failed - returned 0?");
 502                 Posix.unlink(fn);
 503                 return;
 504
 505                 }
 506
 507
 508                 GLib.debug("fn = %s, m5=%s, id= %s", filename, mime_type, this.active_message_id);
 509                 this.query("""
 510
 511                         SELECT attachment_update(
 512                                 %d, -- in_id INT(11),
 513                                 '%s', -- in_mime_type varchar(255),
 514                                 '%s', -- in_created DATETIME,
 515                                 '%s' -- in_mailfort_sig varchar(64)
 516
 517                                 ) as result
 518       """.printf(
 519                 int.parse(file_id),
 520                         this.mysql_escape(mime_type),
 521                         this.created_date,
 522                         this.mysql_escape(this.active_message_x_mailfort_sig)
 523                 ));
 524                  this.mysql.store_result();
 525
 526
 527                 this.used_space_after += file_size;
 528
 529                 var target_fn = "";
 530
 531             if (StripApplication.opt_is_extracting) {
 532                         target_fn = StripApplication.opt_target_path + "/" + this.created_dir +"/"+ file_id  + "-" + filename;
 533                 }
 534
 535             var stored =  "/" + this.created_dir +"/"+ file_id  + "-" + filename;
 536                  this.query("""
 537
 538                         SELECT attachment_update_store(
 539                                 %d, -- in_id INT(11),
 540                                 '%s'  -- in_store_filename varchar(255),
 541
 542
 543                                 ) as result
 544       """.printf(
 545                 int.parse(file_id),
 546                          this.mysql_escape( stored)
 547                 ));
 548
 549         var rep = new GMime.Part.with_type("text","html");
 550         // we have to set up a redirect server - to redirect hpasite... to their internal service..
 551         rep.set_filename(filename);
 552         string txt = "<html><body>"+
 553             "<a href=\"" + StripApplication.opt_replace_link + "/" +
 554                         file_id + "/" + this.created_dir + "/"+chksum+"/"+ GLib.Uri.escape_string( filename) +"\">" +
 555             GLib.Uri.escape_string( filename) + // fixme needs html escaping...
 556             "</a>" +
 557             "</body></html>";
 558
 559         rep.get_content_type().set_parameter("charset", "utf-8");
 560                 rep.set_header("X-strip-id", file_id);
 561                 rep.set_header("X-strip-content-name",  filename);
 562                 rep.set_header("X-strip-path", this.created_dir + "/" + file_id + "-" + filename);
 563                 rep.set_header("X-strip-content-type", mime_type);
 564         var stream =  new GMime.StreamMem.with_buffer(txt.data);
 565         var con = new GMime.DataWrapper.with_stream(stream,GMime.ContentEncoding.DEFAULT);
 566
 567         rep.set_content_object(con);
 568         GLib.debug("Replacing Attachment with HTML");
 569         parent.replace(parent.index_of(attachment), rep);
 570                 this.has_replaced = true;
 571
 572                 if (StripApplication.opt_is_extracting && target_fn.length > 0) {
 573                         var dir = GLib.Path.get_dirname(target_fn);
 574                         if (!FileUtils.test (dir, FileTest.IS_DIR)) {
 575                                 GLib.DirUtils.create_with_parents(dir, 0755);
 576                         }
 577                         GLib.debug("Creating file %s", target_fn);
 578                         if (!FileUtils.test (target_fn, FileTest.EXISTS)) {
 579                                 var from = File.new_for_path (fn);
 580                                 var to =  File.new_for_path (target_fn);
 581                                 from.copy(to, 0, null);
 582
 583                         }
 584                 } else {
 585                         GLib.debug("Skipping extraction %s", target_fn);
 586                 }
 587                 Posix.unlink(fn);
 588
 589
 590
 591     }
 592     public string query(string str)
 593     {
 594             return this.real_query(true, str);
 595     }
 596     public string execute(string str)
 597     {
 598             return this.real_query(false, str);
 599     }
 600     public string real_query(bool need_return, string str)
 601     {
 602                 GLib.debug("Before Query : %u  : %s\n", this.mysql.errno(), this.mysql.error());
 603
 604
 605         if (StripApplication.opt_debug_sql) {
 606                 GLib.debug("SQL: %s\n", str);
 607                 }
 608
 609
 610
 611         var rc=  this.mysql.query(str);
 612         if ( rc != 0 ) {
 613
 614                     GLib.debug("ERROR %u: Query failed: %s\n", this.mysql.errno(), this.mysql.error());
 615                                 Posix.exit(1);
 616                 }
 617
 618
 619         var rs = mysql.use_result();
 620
 621         //GLib.debug("got %d rows", (int) rs.num_rows());
 622
 623         var got_row = false;
 624                 string[] row;
 625                 string ret = "";
 626                 while( (row = rs.fetch_row()) != null) {
 627                         got_row = true;
 628                         ret = row[0];
 629
 630                 }
 631                 if (!need_return) {
 632                 if (StripApplication.opt_debug_sql) {
 633                                 GLib.debug("got %s", got_row ? "=Nothing=" : ret);
 634                         }
 635                         return got_row ? "" : ret;
 636                 }
 637                 if (!got_row) {
 638
 639                          GLib.debug("ERROR : no rows returned");
 640                         Posix.exit(1);
 641                         return "";
 642                 }
 643         if (StripApplication.opt_debug_sql) {
 644                         GLib.debug("got %s", ret);
 645                 }
 646                 return ret;
 647
 648
 649         }
 650
 651     public string mysql_escape(string str)
 652     {
 653             unichar[] value_escaped = new unichar[str.length * 2 + 1];
 654                 this.mysql.real_escape_string ((string) value_escaped, str, str.length);
 655                 return (string) value_escaped;
 656     }
 657
 658     public string  md5_file(string fn) {
 659               Checksum checksum = new Checksum (ChecksumType.MD5);
 660
 661               FileStream stream = FileStream.open (fn, "rb");
 662               uint8 fbuf[100];
 663               size_t size;
 664
 665               while ((size = stream.read (fbuf)) > 0) {
 666                       checksum.update (fbuf, size);
 667               }
 668
 669               unowned string digest = checksum.get_string ();
 670               return digest;
 671     }
 672
 673         string active_path = "";
 674     string active_name = "";
 675     string active_message_id = "";
 676     string active_message_x_mailfort_sig = "";
 677     string active_message_exim_id = "";
 678     bool has_replaced = false;
 679     string created_date = ""; // should be YYYY-mm-dd
 680     string created_dir = ""; // should be YYY/mm/dd
 681
 682     public void scan_file(string path, string name)
 683     {
 684                 GLib.debug("Scan: %s/%s", path,name);
 685
 686                 this.has_replaced = false;
 687         this.active_path = path;
 688         this.active_name = name;
 689         this.active_message_id = "";
 690
 691                 var mailtime = new DateTime.now_local();
 692                 if (StripApplication.opt_scan_mailfort) {
 693                     this.created_dir = this.active_path.substring(this.base_dir.length + 1 );
 694                         this.created_date = this.created_dir.replace("/", "-");
 695                         var bits = this.created_date.split("-");
 696                         mailtime = new DateTime.local(int.parse(bits[0]),int.parse(bits[1]),int.parse(bits[2]),0,0,0);
 697
 698                         var oldest = new  DateTime.now_local();
 699                         oldest = oldest.add_months(-1 * StripApplication.opt_age_oldest);
 700                         var tspan = mailtime.difference(oldest) / GLib.TimeSpan.DAY;
 701
 702                         if (tspan < 0) {
 703                                 GLib.debug("skip file is %d days older than %d months", (int)tspan, StripApplication.opt_age_oldest);
 704                                 return;
 705                         }
 706
 707                         var newest = new  DateTime.now_local();
 708                         newest = newest.add_months(-1 * StripApplication.opt_age_newest);
 709                         tspan = mailtime.difference(newest) / GLib.TimeSpan.DAY;
 710                         if (tspan > 0) {
 711                                 GLib.debug("skip file is %d days newer than %d months", (int)tspan, StripApplication.opt_age_newest);
 712                                 return;
 713                         }
 714
 715                 }
 716
 717
 718                 var fileinfo = File.new_for_path(path +"/" + name)
 719                                         .query_info(GLib.FileAttribute.STANDARD_SIZE+","+GLib.FileAttribute.TIME_MODIFIED
 720                                                 ,GLib.FileQueryInfoFlags.NONE,null);
 721         var file_size = (int) fileinfo.get_size();
 722                 var mod_time = fileinfo.get_modification_time();
 723
 724
 725
 726                 if (!StripApplication.opt_scan_mailfort) {
 727
 728                 // it's a mail directory...
 729                 // use the last modification time? as the default...
 730                  mailtime = new DateTime.from_timeval_utc(mod_time);
 731                  this.created_dir = mailtime.format("%Y/%m/%d");
 732                          this.created_date =  mailtime.format("%Y-%m-%d %H:%M:%S");
 733
 734         }
 735                 // check on age of file...
 736
 737
 738
 739
 740
 741         this.used_space_before += file_size;
 742
 743         var stream = new GMime.StreamFs.for_path (path +"/" + name,Posix.O_RDONLY, 0);
 744         //stream.set_owner(true);
 745         var parser = new GMime.Parser.with_stream(stream);
 746         var message = parser.construct_message();
 747
 748                 if (message == null) {
 749                         GLib.debug("Could not parse file? %s/%s", path,name);
 750                 this.used_space_after += file_size;
 751                 return;
 752                 }
 753
 754
 755                 // check : - is message over a year old?
 756                 // get various msg info..
 757                 this.active_message_id = message.get_message_id();
 758                 this.active_message_x_mailfort_sig = message.get_header("x-mailfort-sig");
 759                 var recvd = message.get_header("received");
 760                 this.active_message_exim_id = "";
 761                 if (recvd != null && recvd.length > 1) {
 762                         GLib.debug("RECV: %s", recvd);
 763                         var lines = recvd.split("\t");
 764                         for (var i = 0; i < lines.length;i++) {
 765                                 var bits = lines[i].strip().split(" ");
 766                                 if (bits[0] == "id") {
 767                                         this.active_message_exim_id = bits[1].replace(";","");
 768
 769                                 }
 770
 771                                 if (lines[i].contains(";")) {
 772                                         var dbits = lines[i].strip().split(";");
 773                                         GLib.debug("Reading time from : %s", dbits[1]);
 774                                         var timez = GMime.utils_header_decode_date(dbits[1], null);
 775                                         if (timez != 0) {
 776                                                 mailtime = new DateTime.from_unix_utc(timez);
 777                                                 this.created_date = mailtime.format("%Y-%m-%d %H:%M:%S");
 778                                                 GLib.debug("Time is %s",this.created_date);
 779                                                 // if it's not mailfort we can use that date to determine where to store it...
 780                                                 if (!StripApplication.opt_scan_mailfort) {
 781                                                         this.created_dir = mailtime.format("%Y/%m/%d");
 782                                                 }
 783                                         } else {
 784                                                 GLib.debug("Could not read time from headers?");
 785                                         }
 786                                 }
 787
 788                         }
 789                 }
 790
 791                 var oldest = new  DateTime.now_local();
 792                 oldest = oldest.add_months(-1 * StripApplication.opt_age_oldest);
 793                 var rtspan = mailtime.difference(oldest) / GLib.TimeSpan.DAY;
 794                 GLib.debug("Checking oldest %d days difference", (int)rtspan   );
 795                 if (rtspan < 0) {
 796                         GLib.debug("skip(2) file is %d days older than %d months", (int)rtspan, StripApplication.opt_age_oldest);
 797                         return;
 798                 }
 799                 var newest = new  DateTime.now_local();
 800                 newest = newest.add_months(-1 * StripApplication.opt_age_newest);
 801                 rtspan = mailtime.difference(newest) / GLib.TimeSpan.DAY;
 802                 if (rtspan > 0) {
 803                         GLib.debug("skip(2) file is %d days newer than %d months : %s", (int)rtspan, StripApplication.opt_age_newest,
 804                                 mailtime.format("%Y-%m-%d %H:%M:%S"));
 805                         return;
 806                 }
 807
 808
 809
 810                 /*
 811                 GLib.debug("Message DATA:\n mid: %s\nmailfort: %s \nexim_id: %s",
 812                         this.active_message_id,
 813                         this.active_message_x_mailfort_sig,
 814                         this.active_message_exim_id
 815                 );
 816                  */
 817
 818                 // DATE?
 819
 820                 var mp = message.get_mime_part();
 821
 822                 if (!(mp is GMime.Multipart)) {
 823                         //GLib.debug("get mimepart does not return a Multipart?");
 824                 this.used_space_after += file_size;
 825                         return;
 826                 }
 827
 828                 var mpc = ((GMime.Multipart)mp).get_count();
 829
 830                 //GLib.debug("Message has %d parts", mpc);
 831                 for (var i =0 ; i < mpc; i++) {
 832                         //GLib.debug("Getting part %d", i);
 833                         var mime_obj = ((GMime.Multipart)mp).get_part(i);
 834             this.handle_part(mp,mime_obj);
 835         }
 836
 837         parser= null;
 838
 839       //  stream.set_owner(false);
 840             //stream.close();
 841         stream = null;//.close();
 842
 843
 844                 if (!this.has_replaced) {
 845                         this.used_space_after += file_size;
 846                         GLib.debug("skpping write file - no replacement occured");
 847                         return;
 848                 }
 849                 string tmpfile = "";
 850                 GMime.Stream outstream = new GMime.StreamNull();
 851                 if (StripApplication.opt_is_replacing) {
 852
 853                         tmpfile = GLib.Environment.get_tmp_dir() +"/" + name;
 854                 outstream = new GMime.StreamFile.for_path (tmpfile,"w");
 855                 ((GMime.StreamFile)outstream).set_owner(true);
 856         }
 857                 if (StripApplication.opt_dump) {
 858                         outstream = new GMime.StreamMem();
 859         }
 860
 861         file_size = (int) message.write_to_stream(outstream);
 862         if (StripApplication.opt_is_replacing) {
 863                 ((GMime.StreamFile)outstream).set_owner(false);
 864         }
 865                 if (StripApplication.opt_dump) {
 866                         var ua = ((GMime.StreamMem)outstream).get_byte_array().data;
 867                         print("%s\n", (string) ua);
 868                 }
 869         message = null;
 870         outstream.flush();
 871         outstream.close();
 872         GLib.debug("finished writing output %d", file_size);
 873
 874         //
 875         outstream = null;
 876
 877
 878         this.used_space_after += file_size;
 879
 880
 881         if (StripApplication.opt_is_replacing) {
 882                 Posix.unlink(path +"/" + name);
 883                 GLib.debug("copy tmp file %s to %s" , tmpfile, path +"/" + name);
 884
 885                 // link will not work, as we are doing it accross file systems
 886                         var from = File.new_for_path (tmpfile);
 887                         var nf =  File.new_for_path (path +"/" + name);
 888                         from.copy(nf, 0, null);
 889
 890
 891                 var newfileinfo = nf.query_info(GLib.FileAttribute.TIME_MODIFIED,GLib.FileQueryInfoFlags.NONE,null);
 892                 newfileinfo.set_modification_time(mod_time);
 893                 nf.set_attributes_from_info(newfileinfo,FileQueryInfoFlags.NONE);
 894                 Posix.unlink(tmpfile);
 895                 }
 896         this.processed++;
 897
 898         if (StripApplication.opt_limit > -1 && this.processed >= StripApplication.opt_limit) {
 899                 GLib.debug("Reached replacement limit");
 900                 Posix.exit(1);
 901         }
 902
 903
 904
 905
 906     }
 907
 908
 909     public void scan_dir(string basepath, string subpath)
 910     {
 911
 912
 913         // determine if path is to old to scan..
 914         if (subpath.length > 0 && StripApplication.opt_scan_mailfort) {
 915                         var year =  int.parse(subpath.substring(1,4));  // "/2000"
 916                         var month = subpath.length > 5 ? int.parse(subpath.substring(6,2)) : 999; // "/2000/12"
 917                         var day = subpath.length > 8 ? int.parse(subpath.substring(9,2)) : 999; // "/2000/12/01"
 918
 919                 var oldest = new  DateTime.now_local();
 920                         oldest = oldest.add_months(-1 * StripApplication.opt_age_oldest);
 921
 922                         //GLib.debug("Checking directory %s is older than min: %d/%d/%d", subpath, oldest.get_year() , oldest.get_month(), oldest.get_day_of_month() );
 923
 924                         if (year < oldest.get_year()) {
 925                                 GLib.debug("Skip directory %s is older than min year: %d", subpath, oldest.get_year());
 926                                 return;
 927                         }
 928                         if (year == oldest.get_year() &&  month < oldest.get_month()) {
 929                                 GLib.debug("Skip directory %s is older than min month: %d/%d", subpath, oldest.get_year() , oldest.get_month() );
 930                                 return;
 931                         }
 932                 if (year == oldest.get_year() &&  month == oldest.get_month() && day < oldest.get_day_of_month()) {
 933                                 GLib.debug("Skip directory %s is older than min day: %d/%d/%d", subpath, oldest.get_year() , oldest.get_month(), oldest.get_day_of_month() );
 934                                 return;
 935                         }
 936
 937                 var newest = new  DateTime.now_local();
 938                         newest = newest.add_months(-1 * StripApplication.opt_age_newest);
 939
 940                         //GLib.debug("Checking directory %s is newer than max: %d/%d/%d", subpath, newest.get_year() , newest.get_month(), newest.get_day_of_month() );
 941
 942                         if (year > newest.get_year()) {
 943                                 GLib.debug("Skip directory %s is newer than max year: %d", subpath, newest.get_year());
 944                                 return;
 945                         }
 946                         if (year == newest.get_year() &&  month != 999 && month > newest.get_month()) {
 947                                 GLib.debug("Skip directory %s is newer than max month: %d/%d", subpath, newest.get_year() , newest.get_month() );
 948                                 return;
 949                         }
 950                 if (year == newest.get_year() &&  month == newest.get_month() &&  day != 999 && day > newest.get_day_of_month()) {
 951                                 GLib.debug("Skip directory %s is newer than max day: %d/%d/%d", subpath, newest.get_year() , newest.get_month(), newest.get_day_of_month() );
 952                                 return;
 953                         }
 954
 955
 956
 957         }
 958
 959
 960         var f = File.new_for_path(basepath + subpath);
 961                 FileEnumerator file_enum;
 962         var cancellable = new Cancellable ();
 963         try {
 964             file_enum = f.enumerate_children(
 965                 FileAttribute.STANDARD_DISPLAY_NAME + "," +   FileAttribute.STANDARD_TYPE,
 966                         FileQueryInfoFlags.NOFOLLOW_SYMLINKS,  // FileQueryInfoFlags.NONE,
 967                         cancellable
 968                 );
 969         } catch (Error e) {
 970                 GLib.debug("Got error scanning dir? %s", e.message);
 971             // FIXME - show error..
 972             return;
 973         }
 974         FileInfo next_file;
 975
 976         while (cancellable.is_cancelled () == false ) {
 977             try {
 978                 next_file = file_enum.next_file (cancellable);
 979             } catch(Error e) {
 980                 GLib.debug("error getting next file? %s", e.message);
 981                 break;
 982             }
 983
 984             if (next_file == null) {
 985                 break;
 986             }
 987
 988
 989                 if (next_file.get_is_symlink()) {
 990                 next_file = null;
 991                 continue;
 992             }
 993
 994             var ds = next_file.get_display_name();
 995             if (next_file.get_file_type() != FileType.DIRECTORY) {
 996
 997
 998
 999                 if (ds[0] == ',') {
1000                         continue;
1001                 }
1002                 // other files to ignore?
1003                 if (Regex.match_simple (".tgz$", ds)) {
1004                         continue;
1005                 }
1006                 this.scan_file(basepath + subpath , ds);
1007                                 if(this.has_replaced) {
1008                          this.report_state("After scanning %s/%s".printf(basepath + subpath , ds));
1009                         }
1010                 continue;
1011             }
1012
1013
1014             //stdout.printf("Monitor.monitor: got file %s : type :%u\n",
1015             //        next_file.get_display_name(), next_file.get_file_type());
1016
1017
1018
1019
1020             // not really needed?? - we are storing attachments in a seperate location now...
1021             if (ds[0] == '.') {
1022                 next_file = null;
1023                 continue;
1024             }
1025             if (ds == "attachments") {
1026                         continue;
1027                 }
1028
1029
1030             var sp = subpath+"/"+next_file.get_display_name();
1031             // skip modules.
1032             //print("got a file : " + sp);
1033
1034             next_file = null;
1035
1036
1037             this.scan_dir(basepath,sp);
1038
1039         }
1040
1041
1042     }
1043     void report_state(string msg)
1044     {
1045         // Saved: 2G  Original 10G : 20%
1046         GLib.debug("Saved : %s (%.1f%%) | Original %s | %s",
1047                         GLib.format_size(this.used_space_before - this.used_space_after),
1048                         100f * ((1f * (this.used_space_before - this.used_space_after)) / (this.used_space_before * 1f)),
1049                         GLib.format_size(this.used_space_before),
1050                         msg
1051                 );
1052
1053         }
1054
1055
1056
1057 }