git.roojs.org Git - app.Builder.js/blob - src/Project/Gtk.vala

   1 //<Script type="text/javascript">
   2 /**
   3  * Gtk projects - normally vala based now..
   4  *
   5  * should have a few extra features..
   6  *
   7  * like:
   8  *   compile flags etc..
   9  *   different versions (eg. different files can compile different versions - eg. for testing.
  10  *
  11  * If we model this like adjuta - then we would need a 'project' file that is actually in
  12  * the directory somewhere... - and is revision controlled etc..
  13  *
  14  * builder.config ??
  15  *
  16  *
  17  *
  18  *
  19  */
  20
  21
  22 namespace Project {
  23         static int gtk_id = 1;
  24
  25
  26         public class Gtk : Project
  27         {
  28
  29                 public Gtk(string path) {
  30
  31
  32                         base(path);
  33                         this.xtype = "Gtk";
  34                         var gid = "project-gtk-%d".printf(gtk_id++);
  35                         this.id = gid;
  36                         this.loadConfig();
  37
  38                 }
  39                 public Gee.HashMap<string,GtkValaSettings> compilegroups;
  40
  41                 public void loadConfig() throws GLib.Error
  42                 {
  43                         // load a builder.config JSON file.
  44                         //
  45                         this.compilegroups = new  Gee.HashMap<string,GtkValaSettings>();
  46
  47
  48                         var fn = this.firstPath() + "/config1.builder";
  49                         GLib.debug("load: " + fn );
  50
  51                         if (!FileUtils.test(fn, FileTest.EXISTS)) {
  52                                 this.compilegroups.set("_default_", new GtkValaSettings("_default_") );
  53                                 return;
  54                         }
  55
  56                         var pa = new Json.Parser();
  57                         pa.load_from_file(fn);
  58                         var node = pa.get_root();
  59
  60                         // should be an array really.
  61                         if (node.get_node_type () != Json.NodeType.ARRAY) {
  62                                 throw new Error.INVALID_FORMAT ("Unexpected element type %s", node.type_name ());
  63                         }
  64
  65                         var obj = node.get_array ();
  66                         for(var i= 0;i<obj.get_length();i++) {
  67                                 var el = obj.get_object_element(i);
  68                                 var vs = new GtkValaSettings.from_json(el);
  69                                 if (vs.name != "_default_") {
  70                                         vs.parent = this.compilegroups.get("_default_");
  71                                 }
  72                                 this.compilegroups.set(vs.name,vs);
  73                         }
  74                         GLib.debug("%s\n",this.configToString ());
  75
  76                 }
  77                 public string configToString()
  78                 {
  79                         var ar = new Json.Array();
  80                         var iter = this.compilegroups.map_iterator();
  81                         while(iter.next()) {
  82
  83                                 ar.add_object_element(iter.get_value().toJson());
  84                         }
  85
  86                         var generator = new Json.Generator ();
  87                         generator.indent = 4;
  88                         generator.pretty = true;
  89                         var node = new Json.Node(Json.NodeType.ARRAY);
  90                         node.set_array(ar);
  91                         generator.set_root(node);
  92                         return generator.to_data(null);
  93                 }
  94
  95                 public void writeConfig()
  96                 {
  97                         var fn = this.firstPath() + "/config1.builder";
  98                         GLib.debug("write: " + fn );
  99
 100
 101                         var f = GLib.File.new_for_path(fn);
 102                         var data_out = new GLib.DataOutputStream(
 103                                         f.replace(null, false, GLib.FileCreateFlags.NONE, null)
 104                         );
 105                         data_out.put_string(this.configToString(), null);
 106                         data_out.close(null);
 107
 108                         return ;
 109
 110                 }
 111                 /**
 112                  *  perhaps we should select the default in the window somewhere...
 113                  */
 114                 public string firstBuildModule()
 115                 {
 116                         var iter = this.compilegroups.map_iterator();
 117                         while(iter.next()) {
 118
 119                                  if (iter.get_value().name == "__default__") {
 120                                          continue;
 121                                  }
 122
 123                                  return iter.get_value().name;
 124                         }
 125                         return "";
 126                 }
 127
 128
 129                 public string relPath(string target)
 130                 {
 131                         var basename = this.firstPath();
 132                         // eg. base = /home/xxx/fred/blogs
 133                         // target = /home/xxx/fred/jones
 134
 135                         // this does not work correctly...
 136                         var bb = basename;
 137                         var prefix = "";
 138                         while (true) {
 139                                 if (    bb.length < target.length &&
 140                                         target.substring(0, bb.length) == bb) {
 141
 142                                         return prefix + target.substring(bb.length +1);
 143                                 }
 144                                 if (bb.length < 1) {
 145                                         throw new Error.INVALID_FORMAT ("Could not work out relative path %s to %s",
 146                                                                         basename, target);
 147                                 }
 148                                 bb = GLib.Path.get_dirname(bb);
 149                                 prefix += "../";
 150
 151                         }
 152
 153                 }
 154                 /**
 155                  * get a list of files for a folder..
 156                  *
 157                  * - in the project manager this has to list all possible compilable
 158                  *   files  - eg. exclue XXX.vala.c or XXX.c with the same name as
 159                  *   a vala file (so to ignore the generated files)
 160                  *
 161                  * - for the editor navigation - this should exclude all files that
 162                  *   are vala based on a bjs file..
 163                  *
 164                  */
 165
 166                 public Gee.ArrayList<string> filesAll(string in_path)
 167                 {
 168                         var ret =  new Gee.ArrayList<string>();
 169
 170                         var dirname = this.resolve_path(
 171                                 this.resolve_path_combine_path(this.firstPath(),in_path));
 172
 173                         GLib.debug("SCAN %s", dirname);
 174                                 // scan the directory for files -- ending with vala || c
 175
 176
 177                         var dir = File.new_for_path(dirname);
 178                         if (!dir.query_exists()) {
 179                                 GLib.debug("SCAN %s - skip - does not exist\n", dirname);
 180                                 return ret;
 181                         }
 182
 183
 184                         try {
 185                                 var file_enum = dir.enumerate_children(
 186                                         GLib.FileAttribute.STANDARD_DISPLAY_NAME,
 187                                         GLib.FileQueryInfoFlags.NONE,
 188                                         null
 189                                 );
 190
 191
 192                                 FileInfo next_file;
 193                                 while ((next_file = file_enum.next_file(null)) != null) {
 194                                         var fn = next_file.get_display_name();
 195
 196                                         GLib.debug("SCAN ADD %s - checking %s\n", dirname, fn);
 197                                         if (!GLib.FileUtils.test(in_path + "/" + fn, GLib.FileTest.IS_REGULAR)) {
 198                                                 continue;
 199                                         }
 200                                         ret.add(in_path + "/" + fn);
 201
 202                                         // any other valid types???
 203
 204                                 }
 205
 206                         } catch(Error e) {
 207                                 GLib.warning("oops - something went wrong scanning the projects\n");
 208                         }
 209
 210                         return ret;
 211                 }
 212
 213                 public Gee.ArrayList<string> filesForCompile(string in_path)
 214                 {
 215                         var allfiles = this.filesAll(in_path);
 216                         var ret =  new Gee.ArrayList<string>();
 217
 218
 219                         for (var i = 0; i < allfiles.size; i ++) {
 220                                 var fn = allfiles.get(i);
 221                                 try {
 222                                         if (Regex.match_simple("\\.vala$", fn)) {
 223                                                 ret.add( fn);
 224                                                 continue;
 225                                         }
 226                                         // vala.c -- ignore..
 227                                         if (Regex.match_simple("\\.vala\\.c$", fn)) {
 228                                                 continue;
 229                                         }
 230                                         // not a c file...
 231                                         if (!Regex.match_simple("\\.c$", fn)) {
 232                                                 continue;
 233                                         }
 234
 235                                         // is the c file the same as a vala file...
 236
 237
 238
 239                                         var vv = (new Regex("\\.c$")).replace( fn, fn.length, 0, ".vala");
 240
 241
 242
 243                                         if (allfiles.index_of( vv) > -1) {
 244                                                 continue;
 245                                         }
 246                                         // add the 'c' file..
 247                                         ret.add(fn);
 248                                 } catch (Error e) {
 249                                         continue;
 250                                 }
 251                         }
 252                         // sort.
 253                         ret.sort((fa,fb) => {
 254                                 return ((string)fa).collate((string) fb);
 255                         });
 256                         return ret;
 257
 258                 }
 259
 260                 public Gee.ArrayList<string> filesForOpen(string in_path)
 261                 {
 262                         var allfiles = this.filesAll(in_path);
 263                         var ret =  new Gee.ArrayList<string>();
 264                         GLib.debug("SCAN %s - %d files",in_path, allfiles.size);
 265
 266                         for (var i = 0; i < allfiles.size; i ++) {
 267                                 var fn = allfiles.get(i);
 268                                 try {
 269
 270                                         if (Regex.match_simple("\\.vala\\.c$", fn)) {
 271                                                 GLib.debug("SKIP %s - vala.c",fn);
 272
 273                                                 continue;
 274                                         }
 275
 276                                         if (Regex.match_simple("\\.bjs$", fn)) {
 277                                                 GLib.debug("SKIP %s - .bjs",fn);
 278                                                 continue;
 279                                         }
 280                                         if (Regex.match_simple("\\.o$", fn)) {
 281                                                 GLib.debug("SKIP %s - .o",fn);
 282                                                 continue;
 283                                         }
 284                                         if (Regex.match_simple("\\~$", fn)) {
 285                                                 GLib.debug("SKIP %s - ~",fn);
 286                                                 continue;
 287                                         }
 288
 289                                         if (Regex.match_simple("^\\.", GLib.Path.get_basename(fn))) {
 290                                                 GLib.debug("SKIP %s - hidden",fn);
 291                                                 continue;
 292                                         }
 293                                         if (Regex.match_simple("\\.vala$", fn)) {
 294                                                 var vv = (new Regex("\\.vala$")).replace( fn, fn.length, 0, ".bjs");
 295                                                 if (allfiles.index_of( vv) > -1) {
 296                                                         GLib.debug("SKIP %s - .vala (got bjs)",fn);
 297                                                         continue;
 298                                                 }
 299                                                 GLib.debug("ADD %s",fn);
 300                                                 ret.add( fn);
 301                                                 continue;
 302                                         }
 303                                         // vala.c -- ignore..
 304
 305                                         // not a c file...
 306                                         if (Regex.match_simple("\\.c$", fn)) {
 307
 308                                                 var vv = (new Regex("\\.c$")).replace( fn, fn.length, 0, ".vala");
 309                                                 if (allfiles.index_of( vv) > -1) {
 310                                                         GLib.debug("SKIP %s - .c (got vala)",fn);
 311                                                         continue;
 312                                                 }
 313                                                 GLib.debug("ADD %s",fn);
 314                                                 ret.add( fn);
 315                                                 continue;
 316                                         }
 317
 318                                         if (GLib.Path.get_basename( fn) == "config1.builder") {
 319                                                 continue;
 320                                         }
 321                                         // not .c / not .vala /not .bjs.. -- other type of file..
 322                                         // allow ???
 323                                         GLib.debug("ADD %s",fn);
 324                                         // add the 'c' file..
 325                                         ret.add(fn);
 326                                 } catch (Error e) {
 327                                         continue;
 328                                 }
 329                         }
 330                         // sort.
 331                         ret.sort((fa,fb) => {
 332                                 return ((string)fa).collate((string) fb);
 333                         });
 334                         return ret;
 335
 336                 }
 337
 338
 339
 340
 341
 342                 public   string  resolve_path_combine_path(string first, string second)
 343                 {
 344                         string ret = first;
 345                         if (first.length > 0 && second.length > 0 && !first.has_suffix("/") && !second.has_prefix("/"))
 346                         {
 347                                 ret += "/";
 348                         }
 349                         //print("combined path = %s",  ret + second);
 350                         return ret + second;
 351                 }
 352                 public   string  resolve_path_times(string part, int times, string? clue = null)
 353                 {
 354                         string ret = "";
 355                         for (int i = 0; i < times; i++)
 356                         {
 357                                 if (clue != null && i > 0)
 358                                 {
 359                                         ret += clue;
 360                                 }
 361                                 ret += part;
 362                         }
 363                         return ret;
 364                 }
 365                 public   string resolve_path(string _path, string? relative = null)
 366                 {
 367                         string path = _path;
 368                         if (relative != null)
 369                         {
 370                                 path = this.resolve_path_combine_path(path, relative);
 371                         }
 372                         string[] parts = path.split("/");
 373                         string[] ret = {};
 374                         int relative_parts = 0;
 375
 376                         foreach (var part in parts)
 377                         {
 378                                 if (part.length < 1 || part == ".")
 379                                 {
 380                                         continue;
 381                                 }
 382
 383                                 if (part == "..")
 384                                 {
 385                                         if (ret.length > 0)
 386                                         {
 387                                                 ret = ret[0: ret.length -1];
 388                                         }
 389                                         else
 390                                         {
 391                                                 relative_parts++;
 392                                         }
 393                                         continue;
 394                                 }
 395
 396                                 ret += part;
 397                         }
 398
 399                         path =  this.resolve_path_combine_path(this.resolve_path_times("..", relative_parts, "/"), string.joinv("/", ret));
 400                         if (_path.has_prefix("/"))
 401                         {
 402                                 path = "/" + path;
 403                         }
 404                         return path;
 405                 }
 406
 407                 public string[] vapidirs()
 408                 {
 409                         string[] ret = {};
 410                         var sources = this.compilegroups.get("_default_").sources;
 411                         for(var i =0; i< sources.size; i++) {
 412
 413                                 var path = this.resolve_path( this.firstPath(), sources.get(i));
 414
 415                                 if (Path.get_basename (path) == "vapi") {
 416                                         GLib.debug("Adding VAPIDIR: %s\n", path);
 417                                         ret += path;
 418                                 }
 419
 420                         }
 421                         return ret;
 422
 423                 }
 424
 425
 426         }
 427         // an object describing a build config (or generic ...)
 428         public class GtkValaSettings : Object {
 429                 public string name;
 430                 public GtkValaSettings? parent;
 431
 432                 public string compile_flags; // generic to all.
 433                 public Gee.ArrayList<string> packages; // list of packages?? some might be genericly named?
 434                 public Gee.ArrayList<string> sources; // list of files+dirs (relative to project)
 435                 public string target_bin;
 436
 437
 438                 public GtkValaSettings(string name)
 439                 {
 440                         this.name = name;
 441                         this.compile_flags = "";
 442                         this.target_bin = "";
 443                         this.packages = new Gee.ArrayList<string>();
 444                         this.sources = new Gee.ArrayList<string>();
 445
 446                 }
 447
 448
 449                 public GtkValaSettings.from_json(Json.Object el) {
 450
 451
 452                         this.name = el.get_string_member("name");
 453                         this.compile_flags = el.get_string_member("compile_flags");
 454                         this.target_bin = el.get_string_member("target_bin");
 455                         // sources and packages.
 456                         this.sources = this.readArray(el.get_array_member("sources"));
 457                         this.packages = this.readArray(el.get_array_member("packages"));
 458
 459                 }
 460
 461
 462
 463                 public Gee.ArrayList<string> readArray(Json.Array ar)
 464                 {
 465                         var ret = new Gee.ArrayList<string>();
 466                         for(var i =0; i< ar.get_length(); i++) {
 467                                 ret.add(ar.get_string_element(i));
 468                         }
 469                         return ret;
 470                 }
 471
 472                 public Json.Object toJson()
 473                 {
 474                         var ret = new Json.Object();
 475                         ret.set_string_member("name", this.name);
 476                         ret.set_string_member("compile_flags", this.compile_flags);
 477                         ret.set_string_member("target_bin", this.target_bin);
 478                         ret.set_array_member("sources", this.writeArray(this.sources));
 479                         ret.set_array_member("packages", this.writeArray(this.packages));
 480                         return ret;
 481                 }
 482                 public Json.Array writeArray(Gee.ArrayList<string> ar) {
 483                         var ret = new Json.Array();
 484                         for(var i =0; i< ar.size; i++) {
 485                                 ret.add_string_element(ar.get(i));
 486                         }
 487                         return ret;
 488                 }
 489
 490
 491         }
 492
 493
 494 }