git.roojs.org Git - app.Builder.js/blob - src/JsRender/JsRender.vala

   1 //<Script type="text/javascript">
   2
   3 namespace JsRender {
   4
   5
   6         public errordomain Error {
   7                 INVALID_FORMAT,
   8                 RENAME_FILE_EXISTS
   9         }
  10
  11         public abstract class JsRender  : Object {
  12                 /**
  13                  * @cfg {Array} doubleStringProps list of properties that can be double quoted.
  14                  */
  15                 public Gee.ArrayList<string> doubleStringProps;
  16
  17                 public string id;
  18                 public string name;   // is the JS name of the file.
  19                 public string fullname;
  20                 public string path;  // is the full path to the file.
  21                 public string parent;  // JS parent.
  22                 public string region;  // RooJS - insert region.
  23
  24                 public string title;  // a title.. ?? nickname.. ??? -
  25                 public string build_module; // module to build if we compile (or are running tests...)
  26
  27
  28                 public string permname;
  29                 public string language;
  30                 public string content_type;
  31                 public string modOrder;
  32                 public string xtype;
  33                 public uint64 webkit_page_id; // set by webkit view - used to extract extension/etc..
  34
  35                 public Project.Project project;
  36                 //Project : false, // link to container project!
  37
  38                 public Node tree; // the tree of nodes.
  39
  40                 public GLib.List<JsRender> cn; // child files.. (used by project ... should move code here..)
  41
  42                 public bool hasParent;
  43
  44                 public bool loaded;
  45
  46                 public Gee.HashMap<string,string> transStrings; // map of md5 -> string.
  47
  48
  49                 public signal void changed (Node? node, string source);
  50
  51
  52                 public signal void compile_notice(string type, string file, int line, string message);
  53                 /**
  54                  * UI componenets
  55                  *
  56                  */
  57                 //public Xcls_Editor editor;
  58
  59
  60
  61                 public JsRender(Project.Project project, string path) {
  62
  63                         this.cn = new GLib.List<JsRender>();
  64                         this.path = path;
  65                         this.project = project;
  66                         this.hasParent = false;
  67                         this.parent = "";
  68                         this.tree = null;
  69                         this.title = "";
  70                         this.region = "";
  71                         this.permname = "";
  72                         this.modOrder = "";
  73                         this.language = "";
  74                         this.content_type = "";
  75                         this.build_module = "";
  76                         this.loaded = false;
  77                         //print("JsRender.cto() - reset transStrings\n");
  78                         this.transStrings = new Gee.HashMap<string,string> ();
  79
  80                         // should use basename reallly...
  81
  82                         var ar = this.path.split("/");
  83                         // name is in theory filename without .bjs (or .js eventually...)
  84                         try {
  85                                 Regex regex = new Regex ("\\.(bjs|js)$");
  86
  87                                 this.name = ar.length > 0 ? regex.replace(ar[ar.length-1],ar[ar.length-1].length, 0 , "") : "";
  88                         } catch (GLib.Error e) {
  89                                 this.name = "???";
  90                         }
  91                         this.fullname = (this.parent.length > 0 ? (this.parent + ".") : "" ) + this.name;
  92
  93                         this.doubleStringProps = new Gee.ArrayList<string>();
  94
  95                 }
  96
  97                 public void renameTo(string name) throws  Error
  98                 {
  99                         if (this.xtype == "PlainFile") {
 100                                 return;
 101                         }
 102                         var bjs = GLib.Path.get_dirname(this.path) +"/" +  name + ".bjs";
 103                         if (FileUtils.test(bjs, FileTest.EXISTS)) {
 104                                 throw new Error.RENAME_FILE_EXISTS("File exists %s\n",name);
 105                         }
 106                         GLib.FileUtils.remove(this.path);
 107                         this.removeFiles();
 108                         // remove other files?
 109
 110                         this.name = name;
 111                         this.path = bjs;
 112
 113                 }
 114
 115
 116
 117                 // not sure why xt is needed... -> project contains xtype..
 118
 119                 public static JsRender factory(string xt, Project.Project project, string path) throws Error
 120                 {
 121
 122                         switch (xt) {
 123                                 case "Gtk":
 124                                         return new Gtk(project, path);
 125                                 case "Roo":
 126                                         return new Roo(project, path);
 127                                 case "PlainFile":
 128                                         return new PlainFile(project, path);
 129                         }
 130                         throw new Error.INVALID_FORMAT("JsRender Factory called with xtype=%s", xt);
 131                         //return null;
 132                 }
 133
 134                 public string toJsonString()
 135                 {
 136                         if (this.xtype == "PlainFile") {
 137                                 return "";
 138                         }
 139                         var generator = new Json.Generator ();
 140                         generator.indent = 4;
 141                         generator.pretty = true;
 142                         var node = new Json.Node(Json.NodeType.OBJECT);
 143                         node.set_object(this.toJsonObject());
 144                         generator.set_root(node);
 145                         return generator.to_data(null);
 146                 }
 147
 148                 public string nickType()
 149                 {
 150                         var ar = this.name.split(".");
 151                         string[] ret = {};
 152                         for (var i =0; i < ar.length -1; i++) {
 153                                 ret += ar[i];
 154                         }
 155                         return string.joinv(".", ret);
 156
 157                 }
 158                 public string nickName()
 159                 {
 160                         var ar = this.name.split(".");
 161                         return ar[ar.length-1];
 162
 163                 }
 164
 165
 166                 public string getIconFileName(bool return_default)
 167                 {
 168
 169                         var m5 = GLib.Checksum.compute_for_string(GLib.ChecksumType.MD5,this.path);
 170
 171                         var dir = GLib.Environment.get_home_dir() + "/.Builder/icons";
 172                         try {
 173                                 if (!FileUtils.test(dir, FileTest.IS_DIR)) {
 174                                          File.new_for_path(dir).make_directory();
 175                                 }
 176                         } catch (GLib.Error e) {
 177                                 // eakk.. what to do here...
 178                         }
 179                         var fname = dir + "/" + m5 + ".png";
 180
 181                         if (!return_default) {
 182                                 print("getIconFileName return %s\n", fname);
 183                                 return fname;
 184                         }
 185
 186                         if (FileUtils.test(fname, FileTest.EXISTS)) {
 187                                 print("getIconFileName return %s\n", fname);
 188                                 return fname;
 189                         }
 190                         // we need to create this somehow...
 191                         print("getIconFileName return %s\n", GLib.Environment.get_home_dir() + "/.Builder/test.jpg");
 192                         return  GLib.Environment.get_home_dir() + "/.Builder/test.jpg";
 193
 194                 }
 195
 196
 197                 public void saveBJS()
 198                 {
 199                     if (!this.loaded) {
 200                             return;
 201                     }
 202                     if (this.xtype == "PlainFile") {
 203                             return;
 204                     }
 205                     var generator = new Json.Generator ();
 206                     generator.indent = 1;
 207                     generator.pretty = true;
 208                     var node = new Json.Node(Json.NodeType.OBJECT);
 209                     node.set_object(this.toJsonObject());
 210                     generator.set_root(node);
 211
 212                     print("WRITE :%s\n " , this.path);// + "\n" + JSON.stringify(write));
 213                     try {
 214                                 this.writeFile(this.path, generator.to_data(null));
 215                         //generator.to_file(this.path);
 216                     } catch(Error e) {
 217                         print("Save failed");
 218                     }
 219                 }
 220
 221
 222
 223                 public abstract void loadItems() throws GLib.Error;
 224
 225
 226
 227
 228                 public string jsonHasOrEmpty(Json.Object obj, string key) {
 229                         return obj.has_member(key) ?
 230                                                 obj.get_string_member(key) : "";
 231                 }
 232
 233
 234                 public Json.Object toJsonObject ()
 235                 {
 236
 237
 238                         var ret = new Json.Object();
 239                         if (this.xtype == "PlainFile") {
 240                                 return ret;
 241                         }
 242
 243                         //ret.set_string_member("id", this.id); // not relivant..
 244                         ret.set_string_member("name", this.name);
 245                         ret.set_string_member("parent", this.parent == null ? "" : this.parent);
 246                         ret.set_string_member("title", this.title == null ? "" : this.title);
 247                         ret.set_string_member("path", this.path);
 248                         //ret.set_string_member("items", this.items);
 249                         ret.set_string_member("permname", this.permname  == null ? "" : this.permname);
 250                         ret.set_string_member("modOrder", this.modOrder  == null ? "" : this.modOrder);
 251                         if (this.project.xtype == "Gtk") {
 252                                 ret.set_string_member("build_module", this.build_module  == null ? "" : this.build_module);
 253                         }
 254
 255                         if (this.transStrings.size > 0) {
 256                                 var tr =  new Json.Object();
 257                                 var iter = this.transStrings.map_iterator();
 258                                 while (iter.next()) {
 259                                         tr.set_string_member(iter.get_value(), iter.get_key());
 260                                 }
 261                                 ret.set_object_member("strings", tr);
 262             }
 263
 264
 265
 266                         var ar = new Json.Array();
 267                         // empty files do not have a tree.
 268                         if (this.tree != null) {
 269                                 ar.add_object_element(this.tree.toJsonObject());
 270                         }
 271                         ret.set_array_member("items", ar);
 272
 273                     return ret;
 274                 }
 275
 276
 277
 278                 public string getTitle ()
 279                 {
 280                     if (this.title.length > 0) {
 281                         return this.title;
 282                     }
 283                     var a = this.path.split("/");
 284                     return a[a.length-1];
 285                 }
 286                 public string getTitleTip()
 287                 {
 288                     if (this.title.length > 0) {
 289                         return "<b>" + this.title + "</b> " + this.path;
 290                     }
 291                     return this.path;
 292                 }
 293                 /*
 294                     sortCn: function()
 295                     {
 296                         this.cn.sort(function(a,b) {
 297                             return a.path > b.path;// ? 1 : -1;
 298                         });
 299                     },
 300                 */
 301                     // should be in palete provider really..
 302
 303
 304                 public Palete.Palete palete()
 305                 {
 306                         // error on plainfile?
 307                         return Palete.factory(this.project.xtype);
 308
 309                 }
 310
 311                 public string guessName(Node ar) // turns the object into full name.
 312                 {
 313                      // eg. xns: Roo, xtype: XXX -> Roo.xxx
 314                     if (!ar.hasXnsType()) {
 315                        return "";
 316                     }
 317
 318                     return ar.get("* xns") + "." + ar.get("* xtype");
 319
 320
 321                 }
 322                 /**
 323                  *  non-atomic write (replacement for put contents, as it creates temporary files.
 324                  */
 325                 public void writeFile(string path, string contents) throws GLib.IOError, GLib.Error
 326                 {
 327
 328
 329                         var f = GLib.File.new_for_path(path);
 330                         var data_out = new GLib.DataOutputStream(
 331                                           f.replace(null, false, GLib.FileCreateFlags.NONE, null)
 332                        );
 333                         data_out.put_string(contents, null);
 334                         data_out.close(null);
 335                 }
 336
 337
 338
 339                 public  Node? lineToNode(int line)
 340                 {
 341                         if (this.tree == null) {
 342                                 return null;
 343                         }
 344                         return this.tree.lineToNode(line);
 345
 346
 347                 }
 348
 349
 350                 public abstract void save();
 351                 public abstract void saveHTML(string html);
 352                 public abstract string toSource() ;
 353                 public abstract string toSourceCode() ; // used by commandline tester..
 354                 public abstract void setSource(string str);
 355                 public abstract string toSourcePreview() ;
 356                 public abstract void removeFiles() ;
 357                  public abstract void  findTransStrings(Node? node );
 358         }
 359
 360 }
 361