git.roojs.org Git - app.Builder.js/blob - src/Resources.vala

   1 /**
   2  * Resources
   3  *
   4  * Idea is to manage resourse used by the app.
   5  *
   6  * The original code downloaded all the resources before it renders the main window
   7  *
   8  * This is a bit annoying as although they do change quite a bit, it's not on every app start
   9  *
  10  * So the Resource fetching behaviour should be a button on the File view page
  11  * That starts the refresh of the resources.
  12  *
  13  * I'm not quite sure how we should flow this - if we do them all at once.. might be a bit of a server
  14  * overload... so sequentially may be best...
  15 */
  16
  17 public class ResourcesItem : Object {
  18         public string target;
  19         public string src;
  20         public string new_sha;
  21         public string cur_sha;
  22         public ResourcesItem(string src, string target, string new_sha)
  23         {
  24                 this.target = target;
  25                 this.src = src;
  26                 this.new_sha = new_sha;
  27                 this.cur_sha = "";
  28                 this.update_cur_sha();
  29                 print("New ResourcesItem %s (%s) => (%s) %s\n", target , this.cur_sha , new_sha, src);
  30         }
  31         public void update_cur_sha()
  32         {
  33                 if (this.target.contains("*")) {
  34                         return;
  35                 }
  36                 var tfn = BuilderApplication.configDirectory() + "/resources/" + this.target;
  37                 if (!GLib.FileUtils.test (tfn, FileTest.IS_REGULAR)) {
  38                         return;
  39                 }
  40                 uint8[] data;
  41                 uint8[] zero = { 0 };
  42                 GLib.FileUtils.get_data(tfn, out data);
  43
  44                 var  file = File.new_for_path (tfn);
  45
  46                 var info = file.query_info(
  47                                  "standard::*",
  48                                 FileQueryInfoFlags.NONE
  49                 );
  50                 var csdata = new GLib.ByteArray.take("blob %s".printf(info.get_size().to_string()).data);
  51                 csdata.append(zero);
  52                 csdata.append(data);
  53
  54                 // git method... blob %d\0...string...
  55                 this.cur_sha = GLib.Checksum.compute_for_data(GLib.ChecksumType.SHA1, csdata.data       );
  56         }
  57
  58 }
  59
  60
  61 public class Resources : Object
  62 {
  63
  64      public signal void updateProgress(uint cur_pos, uint total);
  65
  66      static Resources singleton_val;
  67
  68
  69      Gee.ArrayList<ResourcesItem> fetch_files;
  70
  71      public static Resources singleton()
  72      {
  73         if (singleton_val == null) {
  74             singleton_val = new Resources();
  75             singleton_val.ref();
  76         }
  77         return singleton_val;
  78
  79      }
  80          public Resources ()
  81          {
  82                 this.initFiles();
  83         }
  84
  85
  86         public void initFiles()
  87         {
  88                 string[] avail_files = {
  89                         "roodata.json",
  90                         "*",
  91                         "Editors/*.js",
  92                         "vapi/*"
  93
  94                 };
  95                 this.fetch_files = new Gee.ArrayList<ResourcesItem>();
  96                 for (var i=0;i < avail_files.length; i++) {
  97                         var target = avail_files[i];
  98                         var src = "https://raw.githubusercontent.com/roojs/app.Builder.js/master/resources/" + target;
  99
 100                         if (target == "roodata.json") {
 101                                 src = "https://raw.githubusercontent.com/roojs/roojs1/master/docs/json/roodata.json";
 102                                 //src = "http://git.roojs.org/?p=roojs1;a=blob_plain;f=docs/json/roodata.json";
 103                         }
 104                         if (target.contains("*")) {
 105                                 var split = target.split("*");
 106
 107                                 src = "https://api.github.com/repos/roojs/app.Builder.js/contents/resources/" + split[0];
 108                                 if (split[0] == "vapi/") {
 109                                         src = "https://api.github.com/repos/roojs/app.Builder.js/contents/src/vapi";
 110
 111                                 }
 112
 113                         }
 114
 115                         this.fetch_files.add(new ResourcesItem(src,target, ""));
 116                 }
 117
 118         }
 119
 120
 121      int fetch_pos = 0;
 122      public void fetchStart()
 123      {
 124             this.initFiles();
 125             if (this.fetch_pos > 0) { // only fetch one at a time...
 126                 return;
 127             }
 128             this.fetch_pos =0;
 129             this.fetchNext();
 130
 131      }
 132      public void fetchNext()
 133     {
 134         var cur = this.fetch_pos;
 135         this.fetch_pos++;
 136         this.updateProgress(this.fetch_pos, this.fetch_files.size); // min=0;
 137
 138
 139         if (this.fetch_pos > this.fetch_files.size) {
 140                          this.updateProgress(0,0);
 141                      this.fetch_pos = 0;
 142                      return;
 143
 144                 }
 145
 146                 this.fetchResourceFrom ( this.fetch_files.get(cur) );
 147
 148
 149          }
 150          /**
 151           *  called on start to check we have all the required files..
 152           */
 153          public void checkResources()
 154          {
 155                 bool needsload = false;
 156
 157                 // this has to check the required files, not the list...
 158                 string[] required =  {
 159                         "bootstrap.builder.html",
 160                         "Gir.overides",
 161                         "GtkUsage.txt",
 162                         "mailer.builder.html",
 163                         "roo.builder.html",
 164                         "roo.builder.js",
 165                         "roodata.json",
 166                         "RooUsage.txt"
 167                 };
 168
 169                 for (var i = 0; i <  required.length; i++ ) {
 170
 171                         if (!FileUtils.test(
 172                                 BuilderApplication.configDirectory() + "/resources/"  + required[i],
 173                                 FileTest.EXISTS
 174                                 )) {
 175                                 needsload = true;
 176                         }
 177                 }
 178                 if (!needsload) {
 179                         return;
 180                 }
 181                 this.fetchStart();
 182          }
 183
 184         public void parseDirectory(string json, string target)
 185         {
 186                 print("%s\n", json);
 187                 var pa = new Json.Parser();
 188                 pa.load_from_data(json);
 189                 var node = pa.get_root();
 190                 if (node.get_node_type () != Json.NodeType.ARRAY) {
 191                         return;
 192                         //throw new Error.INVALID_FORMAT ("Unexpected element type %s", node.type_name ());
 193                 }
 194
 195                 var split = target.split("*");
 196                 var ar = node.get_array ();
 197                 for(var i = 0; i < ar.get_length(); i++) {
 198                         var ob = ar.get_object_element(i);
 199                         var n = ob.get_string_member("name");
 200                         if (ob.get_string_member("type") == "dir") {
 201                                 continue;
 202                         }
 203                         if (split.length > 1 && !n.has_suffix(split[1])) {
 204                                 // not needed..
 205                                 continue;
 206                         }
 207                         if (this.files_has_target(split[0] + n)) {
 208                                 continue;
 209                         }
 210
 211
 212
 213                         var src = ob.get_string_member("download_url");
 214                                         // "https://raw.githubusercontent.com/roojs/app.Builder.js/master/resources/" + split[0] + n;
 215                         var add = new ResourcesItem(src, split[0] + n, ob.get_string_member("sha") );
 216                         //add.new_sha = ob.get_string_member("sha");
 217                         this.fetch_files.add(add);
 218
 219                 }
 220         }
 221         public bool files_has_target(string target)
 222         {
 223                 for (var i = 0; i <  this.fetch_files.size; i++ ) {
 224                         if (this.fetch_files.get(i).target == target) {
 225                                 return true;
 226                         }
 227                 }
 228                 return false;
 229
 230         }
 231
 232
 233
 234
 235     public void fetchResourceFrom(ResourcesItem item)
 236     {
 237                 if (item.new_sha != "" && item.new_sha == item.cur_sha) {
 238                         this.fetchNext();
 239                         return;
 240                 }
 241
 242                 // fetch...
 243                 print("downloading %s \nto : %s\n", item.src,item.target);
 244                 var session = new Soup.Session ();
 245                 session.user_agent = "App Builder ";
 246             var message = new Soup.Message ("GET",  item.src );
 247         session.queue_message (message, (sess, mess) => {
 248
 249                         if (item.target.contains("*")) {
 250                                 // then it's a directory listing in JSON, and we need to add any new items to our list..
 251                                 // it's used to fetch Editors (and maybe other stuff..)
 252                                 this.parseDirectory((string) message.response_body.data,item.target );
 253                                 this.fetchNext();
 254                                 return;
 255                         }
 256
 257
 258                         var tfn = BuilderApplication.configDirectory() + "/resources/" + item.target;
 259
 260
 261                         // create parent directory if needed
 262                         if (!GLib.FileUtils.test (GLib.Path.get_dirname(tfn), FileTest.IS_DIR)) {
 263                                 var f =  GLib.File.new_for_path(GLib.Path.get_dirname(tfn));
 264                                 f.make_directory_with_parents ();
 265                         }
 266
 267
 268
 269
 270                         // set data??? - if it's binary?
 271             FileUtils.set_contents(  tfn, (string) message.response_body.data );
 272
 273             switch (item.target) {
 274                                 case "Gir.overides":
 275                                         Palete.Gir.factory("Gtk").loadOverrides(true);
 276                                         break;
 277
 278                                 case "GtkUsage.txt":
 279                                         Palete.factory("Gtk").load();
 280                                         break;
 281
 282                                 case "roodata.json":
 283                                         Palete.factory("Roo").classes  = null;
 284                                         Palete.factory("Roo").load();
 285                                         break;
 286
 287                                 default:
 288                                         break;
 289                         }
 290
 291
 292
 293
 294
 295
 296             this.fetchNext();
 297
 298         });
 299
 300
 301     }
 302 }