git.roojs.org Git - gnome.gobject-introspection/blob - m4/python.m4

   1 ## this one is commonly used with AM_PATH_PYTHONDIR ...
   2 dnl a macro to check for ability to create python extensions
   3 dnl  AM_CHECK_PYTHON_HEADERS([ACTION-IF-POSSIBLE], [ACTION-IF-NOT-POSSIBLE])
   4 dnl function also defines PYTHON_INCLUDES
   5 AC_DEFUN([AM_CHECK_PYTHON_HEADERS],
   6 [AC_REQUIRE([AM_PATH_PYTHON])
   7 AC_MSG_CHECKING(for headers required to compile python extensions)
   8 dnl deduce PYTHON_INCLUDES
   9 py_prefix=`$PYTHON -c "import sys; print sys.prefix"`
  10 py_exec_prefix=`$PYTHON -c "import sys; print sys.exec_prefix"`
  11 PYTHON_INCLUDES="-I${py_prefix}/include/python${PYTHON_VERSION}"
  12 if test "$py_prefix" != "$py_exec_prefix"; then
  13   PYTHON_INCLUDES="$PYTHON_INCLUDES -I${py_exec_prefix}/include/python${PYTHON_VERSION}"
  14 fi
  15 AC_SUBST(PYTHON_INCLUDES)
  16 dnl check if the headers exist:
  17 save_CPPFLAGS="$CPPFLAGS"
  18 CPPFLAGS="$CPPFLAGS $PYTHON_INCLUDES"
  19 AC_TRY_CPP([#include <Python.h>],dnl
  20 [AC_MSG_RESULT(found)
  21 $1],dnl
  22 [AC_MSG_RESULT(not found)
  23 $2])
  24 CPPFLAGS="$save_CPPFLAGS"
  25 ])